Warning, /frameworks/solid/cmake/FindPList.cmake is written in an unsupported language. File is not indexed.

0001 #.rst:
0002 # FindPList
0003 # --------
0004 #
0005 # Try to find the plist library, once done this will define:
0006 #
0007 #  ``PList_FOUND``
0008 #      System has libplist.
0009 #
0010 #  ``PList_INCLUDE_DIRS``
0011 #      The libplist include directory.
0012 #
0013 # ``PList_LIBRARIES``
0014 #     The libplist libraries.
0015 #
0016 # ``PList_VERSION``
0017 #     The libplist version.
0018 #
0019 # If ``PList_FOUND`` is TRUE, the following imported target
0020 # will be available:
0021 #
0022 # ``PList::PList``
0023 #     The libplist library
0024 
0025 #=============================================================================
0026 # SPDX-FileCopyrightText: 2020 MBition GmbH
0027 # SPDX-FileContributor: Kai Uwe Broulik <kai_uwe.broulik@mbition.io>
0028 #
0029 # SPDX-License-Identifier: BSD-3-Clause
0030 #=============================================================================
0031 
0032 find_package(PkgConfig QUIET)
0033 pkg_search_module(PC_libplist QUIET libplist-2.0 libplist)
0034 
0035 find_path(PList_INCLUDE_DIRS NAMES plist/plist.h HINTS ${PC_libplist_INCLUDE_DIRS})
0036 find_library(PList_LIBRARIES NAMES plist-2.0 plist HINTS ${PC_libplist_LIBRARY_DIRS})
0037 
0038 set(PList_VERSION ${PC_libplist_VERSION})
0039 
0040 include(FindPackageHandleStandardArgs)
0041 find_package_handle_standard_args(PList
0042     FOUND_VAR PList_FOUND
0043     REQUIRED_VARS PList_INCLUDE_DIRS PList_LIBRARIES
0044     VERSION_VAR PList_VERSION
0045 )
0046 
0047 mark_as_advanced(PList_INCLUDE_DIRS PList_LIBRARIES)
0048 
0049 if(PList_FOUND AND NOT TARGET PList::PList)
0050     add_library(PList::PList UNKNOWN IMPORTED)
0051     set_target_properties(PList::PList PROPERTIES
0052         IMPORTED_LOCATION "${PList_LIBRARIES}"
0053         INTERFACE_INCLUDE_DIRECTORIES "${PList_INCLUDE_DIRS}"
0054         INTERFACE_COMPILE_OPTIONS "${PC_libplist_CFLAGS_OTHER}"
0055     )
0056 endif()
0057 
0058 include(FeatureSummary)
0059 set_package_properties(PList PROPERTIES
0060     DESCRIPTION "library to handle Apple property list format"
0061     URL "https://www.libimobiledevice.org/"
0062 )