purpose/src/CMakeLists.txt

0001 qt_add_resources(purpose_SRCS standard-plugin-types.qrc)
0002
0003 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake-paths.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/cmake-paths.h)
0004
0005 ecm_qt_declare_logging_category(external_process_debug_SRCS
0006     HEADER purpose_external_process_debug.h
0007     IDENTIFIER PURPOSE_EXTERNAL_PROCESS_LOG
0008     CATEGORY_NAME kf.purpose.externalprocess
0009     OLD_CATEGORY_NAMES kf5.purpose.externalprocess
0010     DESCRIPTION "purpose external process"
0011     EXPORT PURPOSE
0012 )
0013
0014 add_library(KF5Purpose
0015     ${external_process_debug_SRCS}
0016     pluginbase.cpp
0017     job.cpp
0018     alternativesmodel.cpp
0019     configuration.cpp
0020     helper.cpp
0021     externalprocess/processjob.cpp
0022     jobcontroller.cpp
0023     ${purpose_SRCS}
0024 )
0025
0026 target_include_directories(KF5Purpose PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0027                                              "$<BUILD_INTERFACE:${Purpose_BINARY_DIR}>"
0028                                       INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/purpose>"
0029 )
0030 target_link_libraries(KF5Purpose
0031     PUBLIC
0032         KF5::CoreAddons
0033         Qt${QT_MAJOR_VERSION}::Gui
0034     PRIVATE
0035         Qt${QT_MAJOR_VERSION}::DBus
0036         Qt${QT_MAJOR_VERSION}::Network #QLocalSocket
0037         KF5::ConfigCore
0038 )
0039 set_target_properties(KF5Purpose PROPERTIES VERSION ${PURPOSE_VERSION}
0040                                           SOVERSION ${PURPOSE_SOVERSION}
0041                                           EXPORT_NAME Purpose
0042 )
0043
0044 install(TARGETS KF5Purpose EXPORT KF5PurposeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0045 add_library(KF5::Purpose ALIAS KF5Purpose)
0046
0047 generate_export_header(KF5Purpose EXPORT_FILE_NAME ${Purpose_BINARY_DIR}/purpose/purpose_export.h BASE_NAME Purpose)
0048 ecm_generate_headers(Purpose_CamelCase_HEADERS
0049     HEADER_NAMES
0050         PluginBase
0051         AlternativesModel
0052         Job
0053         Configuration
0054     REQUIRED_HEADERS Purpose_HEADERS
0055     PREFIX Purpose
0056 )
0057
0058 install(FILES ${Purpose_CamelCase_HEADERS}
0059         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/purpose/Purpose/
0060         COMPONENT Devel)
0061 install(FILES
0062   ${Purpose_BINARY_DIR}/purpose/purpose_export.h
0063   ${Purpose_HEADERS}
0064   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/purpose/purpose COMPONENT Devel
0065 )
0066
0067 add_executable(purposeprocess externalprocess/purposeprocess_main.cpp helper.cpp ${external_process_debug_SRCS})
0068 ecm_mark_nongui_executable(purposeprocess)
0069 target_link_libraries(purposeprocess KF5::Purpose Qt${QT_MAJOR_VERSION}::Network Qt${QT_MAJOR_VERSION}::Widgets)
0070 install(TARGETS purposeprocess DESTINATION ${KDE_INSTALL_LIBEXECDIR_KF})
0071
0072 add_subdirectory(plugins)
0073 add_subdirectory(quick)
0074 add_subdirectory(widgets)
0075 add_subdirectory(fileitemactionplugin)
0076
0077 ecm_qt_install_logging_categories(
0078     EXPORT PURPOSE
0079     FILE purpose.categories
0080     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0081 )