src/scanner/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2022 Volker Krause <vkrause@kde.org>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-prison-scanner.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-prison-scanner.h)
0005
0006 add_library(KF5PrisonScanner)
0007 add_library(KF5::PrisonScanner ALIAS KF5PrisonScanner)
0008
0009 set_target_properties(KF5PrisonScanner PROPERTIES
0010     VERSION     ${PRISON_VERSION}
0011     SOVERSION   ${PRISON_SOVERSION}
0012     EXPORT_NAME PrisonScanner
0013 )
0014
0015 target_sources(KF5PrisonScanner PRIVATE
0016     format.cpp
0017     scanresult.cpp
0018     videoscanner.cpp
0019     videoscannerframe.cpp
0020     videoscannerworker.cpp
0021 )
0022 kde_source_files_enable_exceptions(videoscannerworker.cpp)
0023
0024 ecm_generate_export_header(KF5PrisonScanner
0025     BASE_NAME PrisonScanner
0026     GROUP_BASE_NAME KF
0027     VERSION ${KF_VERSION}
0028 )
0029 target_include_directories(KF5PrisonScanner
0030     INTERFACE
0031         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/PrisonScanner>"
0032         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Prison>" # module version header
0033 )
0034 target_link_libraries(KF5PrisonScanner
0035     PUBLIC
0036         Qt${QT_MAJOR_VERSION}::Multimedia
0037     PRIVATE
0038         Qt${QT_MAJOR_VERSION}::Core
0039         ZXing::ZXing
0040 )
0041
0042 install(TARGETS KF5PrisonScanner EXPORT KF5PrisonTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0043
0044 ecm_generate_headers(PrisonScanner_CamelCase_HEADERS
0045     HEADER_NAMES
0046         Format
0047         ScanResult
0048         VideoScanner
0049     OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/Prison
0050     REQUIRED_HEADERS PrisonScanner_HEADERS
0051 )
0052
0053 install(
0054     FILES
0055         ${PrisonScanner_CamelCase_HEADERS}
0056         ${PrisonScanner_HEADERS}
0057         ${CMAKE_CURRENT_BINARY_DIR}/prisonscanner_export.h
0058     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/PrisonScanner/Prison
0059     COMPONENT Devel
0060 )
0061
0062 if(BUILD_QCH)
0063     ecm_add_qch(
0064         KF5PrisonScanner_QCH
0065         NAME PrisonScanner
0066         BASE_NAME KF5PrisonScanner
0067         VERSION ${KF_VERSION}
0068         ORG_DOMAIN org.kde
0069         SOURCES # using only public headers, to cover only public API
0070             ${PrisonScanner_HEADERS}
0071         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0072         LINK_QCHS
0073             Qt${QT_MAJOR_VERSION}Multimedia_QCH
0074         INCLUDE_DIRS
0075             ${CMAKE_CURRENT_BINARY_DIR}
0076         BLANK_MACROS
0077             PRISONSCANNER_EXPORT
0078             PRISONSCANNER_DEPRECATED
0079             PRISONSCANNER_DEPRECATED_EXPORT
0080             "PRISONSCANNER_DEPRECATED_VERSION(x, y, t)"
0081             "PRISONSCANNER_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0082         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0083         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0084         COMPONENT Devel
0085     )
0086 endif()