prison/cmake/FindDmtx.cmake

0001 #.rst:
0002 # FindDmtx
0003 # --------
0004 #
0005 # Try to find the DataMatrix library.
0006 #
0007 # This will define the following variables:
0008 #
0009 # ``Dmtx_FOUND``
0010 #     True if the datamatrix library is available.
0011 #
0012 # ``Dmtx_INCLUDE_DIRS``
0013 #     the datamatrix library include dirs.
0014 #     This variable shall be passed to target_include_libraries() calls if
0015 #     the target is not used for linking.
0016 #
0017 # ``Dmtx_LIBRARIES``
0018 #     the libraries used to link datamatrix.
0019 #     This can be passed to target_link_libraries instead of
0020 #     the ``Dmtx::Dmtx`` target.
0021 #
0022 # If ``Dmtx_FOUND`` is TRUE, the following imported target
0023 # will be available:
0024 #
0025 # ``Dmtx::Dmtx``
0026 #     The datamatrix library.
0027 #
0028 # Imported target since 5.27.0
0029 #
0030 #=============================================================================
0031 # SPDX-FileCopyrightText: 2010 Sune Vuorela <sune@debian.org>
0032 # SPDX-License-Identifier: BSD-3-Clause
0033 #=============================================================================
0034
0035 find_path(Dmtx_INCLUDE_DIRS dmtx.h)
0036
0037 find_library(Dmtx_LIBRARIES NAMES dmtx)
0038
0039 include(FindPackageHandleStandardArgs)
0040
0041 find_package_handle_standard_args(Dmtx
0042     FOUND_VAR Dmtx_FOUND
0043     REQUIRED_VARS Dmtx_LIBRARIES Dmtx_INCLUDE_DIRS
0044 )
0045
0046 if(Dmtx_FOUND AND NOT TARGET Dmtx::Dmtx)
0047   add_library(Dmtx::Dmtx UNKNOWN IMPORTED)
0048   set_target_properties(Dmtx::Dmtx PROPERTIES
0049   IMPORTED_LOCATION "${Dmtx_LIBRARIES}"
0050   INTERFACE_INCLUDE_DIRECTORIES "${Dmtx_INCLUDE_DIRS}")
0051 endif()
0052
0053 mark_as_advanced(Dmtx_INCLUDE_DIRS Dmtx_LIBRARIES)
0054
0055 include(FeatureSummary)
0056 set_package_properties(Dmtx PROPERTIES
0057   URL "https://github.com/dmtx/libdmtx"
0058   DESCRIPTION "The Datamatrix library"
0059 )
0060