frameworks/modemmanager-qt/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(ModemManagerQt VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0013
0014 find_package(ModemManager 1.0 REQUIRED)
0015
0016 include(KDEInstallDirs)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018 include(KDECMakeSettings)
0019
0020 include(KDEGitCommitHooks)
0021 include(ECMDeprecationSettings)
0022
0023 set(REQUIRED_QT_VERSION 6.5.0)
0024 find_package(Qt6 ${REQUIRED_QT_VERSION} REQUIRED Core DBus Xml)
0025
0026 add_definitions(${QT_DEFINITIONS})
0027
0028 remove_definitions(-DQT_NO_FOREACH) # set by KDEFrameworkCompilerSettings
0029
0030 include(ECMGenerateExportHeader)
0031 include(ECMSetupVersion)
0032 include(ECMGenerateHeaders)
0033 include(ECMAddQch)
0034 include(ECMQtDeclareLoggingCategory)
0035
0036 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0037 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0038
0039 set(modemmanagerqt_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/modemmanagerqt_version.h")
0040 ecm_setup_version(PROJECT VARIABLE_PREFIX MODEMMANAGERQT
0041                         VERSION_HEADER "${modemmanagerqt_version_header}"
0042                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ModemManagerQtConfigVersion.cmake"
0043                         SOVERSION 6)
0044 ecm_set_disabled_deprecation_versions(
0045     QT 6.5
0046 )
0047
0048 # Enable unit testing
0049 if (BUILD_TESTING)
0050     add_subdirectory(src/fakemodem)
0051     add_subdirectory(autotests)
0052 endif ()
0053
0054 ##################  examples  ################################
0055 option(BUILD_EXAMPLES "Build example applications" FALSE)
0056 if (BUILD_EXAMPLES)
0057     add_subdirectory(examples)
0058 endif(BUILD_EXAMPLES)
0059
0060 add_subdirectory(src)
0061
0062 # create a Config.cmake and a ConfigVersion.cmake file and install them
0063 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ModemManagerQt")
0064
0065 if (BUILD_QCH)
0066     ecm_install_qch_export(
0067         TARGETS KF6ModemManagerQt_QCH
0068         FILE KF6ModemManagerQtQchTargets.cmake
0069         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0070         COMPONENT Devel
0071     )
0072     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ModemManagerQtQchTargets.cmake\")")
0073 endif()
0074
0075 include(CMakePackageConfigHelpers)
0076
0077 configure_package_config_file(
0078   "${CMAKE_CURRENT_SOURCE_DIR}/KF6ModemManagerQtConfig.cmake.in"
0079   "${CMAKE_CURRENT_BINARY_DIR}/KF6ModemManagerQtConfig.cmake"
0080   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0081 )
0082
0083 install(FILES
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF6ModemManagerQtConfig.cmake"
0085   "${CMAKE_CURRENT_BINARY_DIR}/KF6ModemManagerQtConfigVersion.cmake"
0086   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087   COMPONENT Devel
0088 )
0089
0090 install(EXPORT KF6ModemManagerQtTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ModemManagerQtTargets.cmake NAMESPACE KF6:: )
0091
0092 install(FILES
0093    ${modemmanagerqt_version_header}
0094   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt COMPONENT Devel
0095 )
0096
0097 include(ECMFeatureSummary)
0098 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0099
0100 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)