kxmlrpcclient/src/CMakeLists.txt

0001 add_library(KF5XmlRpcClient)
0002 add_library(KF5::XmlRpcClient ALIAS KF5XmlRpcClient)
0003
0004 target_sources(KF5XmlRpcClient PRIVATE
0005     client.cpp
0006     client.h
0007     query.cpp
0008     query.h
0009     query_p.h
0010 )
0011
0012 ecm_qt_declare_logging_category(KF5XmlRpcClient
0013     HEADER kxmlrpcclient_debug.h
0014     IDENTIFIER KXMLRPCCLIENT_LOG
0015     CATEGORY_NAME kf.xmlrpcclient
0016     OLD_CATEGORY_NAMES log_kxmlrpcclient org.kde.pim.kxmlrpcclient kf5.kxmlrpcclient
0017     DESCRIPTION "kxmlrpcclient (framework)"
0018     EXPORT KXMLRPCCLIENT
0019 )
0020
0021 generate_export_header(KF5XmlRpcClient BASE_NAME kxmlrpcclient)
0022
0023 target_include_directories(KF5XmlRpcClient INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KXmlRpcClient;${KDE_INSTALL_INCLUDEDIR_KF5}/KXmlRpcClient/kxmlrpcclient>")
0024
0025 target_link_libraries(KF5XmlRpcClient
0026 PRIVATE
0027    KF5::KIOCore
0028    KF5::I18n
0029    Qt5::Xml
0030 )
0031
0032 set_target_properties(KF5XmlRpcClient PROPERTIES
0033     VERSION ${KXMLRPCCLIENT_VERSION}
0034     SOVERSION ${KXMLRPCCLIENT_SOVERSION}
0035     EXPORT_NAME XmlRpcClient
0036 )
0037
0038 ecm_generate_headers(KXmlRpcClient_CamelCase_HEADERS
0039   HEADER_NAMES
0040   Client
0041   PREFIX KXmlRpcClient
0042   REQUIRED_HEADERS KXmlRpcClient_HEADERS
0043 )
0044
0045 install(TARGETS KF5XmlRpcClient EXPORT KF5XmlRpcClientTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
0046
0047
0048 ecm_generate_pri_file(BASE_NAME KXmlRpcClient
0049     LIB_NAME KF5XmlRpcClient
0050     DEPS "" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KXmlRpcClient
0051 )
0052
0053 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0054
0055
0056 install(FILES ${KXmlRpcClient_CamelCase_HEADERS}
0057   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KXmlRpcClient/KXmlRpcClient/)
0058
0059 install(FILES
0060   ${CMAKE_CURRENT_BINARY_DIR}/kxmlrpcclient_export.h
0061   ${KXmlRpcClient_HEADERS}
0062   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KXmlRpcClient/kxmlrpcclient/
0063   COMPONENT Devel
0064 )
0065
0066 ecm_qt_install_logging_categories(
0067     EXPORT KXMLRPCCLIENT
0068     FILE kxmlrpcclient.categories
0069     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0070 )
0071
0072 if(BUILD_QCH)
0073     ecm_add_qch(
0074         KF5XmlRpcClient_QCH
0075         NAME KXmlRpcClient
0076         BASE_NAME KF5XmlRpcClient
0077         VERSION ${KF_VERSION}
0078         ORG_DOMAIN org.kde
0079         SOURCES # using only public headers, to cover only public API
0080             ${KXmlRpcClient_HEADERS}
0081         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0082         LINK_QCHS
0083             Qt5Core_QCH
0084         INCLUDE_DIRS
0085             ${CMAKE_CURRENT_BINARY_DIR}
0086         BLANK_MACROS
0087             KXMLRPCCLIENT_EXPORT
0088             KXMLRPCCLIENT_DEPRECATED
0089             KXMLRPCCLIENT_DEPRECATED_EXPORT
0090         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0091         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0092         COMPONENT Devel
0093     )
0094 endif()
0095