Warning, /frameworks/kxmlgui/src/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 add_library(KF6XmlGui)
0002 add_library(KF6::XmlGui ALIAS KF6XmlGui)
0003 
0004 set_target_properties(KF6XmlGui PROPERTIES
0005     VERSION     ${KXMLGUI_VERSION}
0006     SOVERSION   ${KXMLGUI_SOVERSION}
0007     EXPORT_NAME XmlGui
0008 )
0009 
0010 if (HAVE_GLOBALACCEL)
0011     target_link_libraries(KF6XmlGui PRIVATE KF6::GlobalAccel)
0012 endif ()
0013 if(WIN32)
0014     target_link_libraries(KF6XmlGui PRIVATE secur32) # GetUserNameEx()
0015 endif()
0016 
0017 configure_file(config-xmlgui.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-xmlgui.h )
0018 
0019 target_sources(KF6XmlGui PRIVATE
0020   kaboutapplicationdialog.cpp
0021   kaboutapplicationcomponentlistdelegate_p.cpp
0022   kaboutapplicationcomponentmodel_p.cpp
0023   kaboutapplicationlistview_p.cpp
0024   kaboutapplicationpersonlistdelegate_p.cpp
0025   kaboutapplicationpersonmodel_p.cpp
0026   kaboutkdedialog_p.cpp
0027   kaboutplugindialog.cpp
0028   kabstractaboutdialog_p.cpp
0029   kactioncategory.cpp
0030   kactioncollection.cpp
0031   kactionconflictdetector.cpp
0032   kbugreport.cpp
0033   kedittoolbar.cpp
0034   khelpmenu.cpp
0035   kkeysequencewidget.cpp
0036   klicensedialog_p.cpp
0037   kmainwindow.cpp
0038   kmenumenuhandler_p.cpp
0039   kshortcuteditwidget.cpp
0040   kshortcutschemeseditor.cpp
0041   kshortcutschemeshelper.cpp
0042   kshortcutsdialog.cpp
0043   kshortcutseditor.cpp
0044   kshortcutseditordelegate.cpp
0045   kshortcutseditoritem.cpp
0046   kshortcutwidget.cpp
0047   kswitchlanguagedialog_p.cpp
0048   ktoggletoolbaraction.cpp
0049   ktoolbar.cpp
0050   ktoolbarhandler.cpp
0051   ktoolbarhelper.cpp
0052   ktooltiphelper.cpp
0053   kxmlguibuilder.cpp
0054   kxmlguiclient.cpp
0055   kxmlguifactory.cpp
0056   kxmlguifactory_p.cpp
0057   kxmlguiversionhandler.cpp
0058   kxmlguiwindow.cpp
0059   kundoactions.cpp
0060   kcheckaccelerators.cpp
0061 )
0062 if (TARGET Qt6::DBus)
0063     target_sources(KF6XmlGui PRIVATE
0064         kmainwindowiface.cpp
0065     )
0066 endif()
0067 
0068 # add the resource file
0069 target_sources(KF6XmlGui PRIVATE
0070     kxmlgui.qrc
0071 )
0072 
0073 ecm_qt_declare_logging_category(KF6XmlGui
0074     HEADER debug.h
0075     IDENTIFIER DEBUG_KXMLGUI
0076     CATEGORY_NAME kf.xmlgui
0077     OLD_CATEGORY_NAMES kf5.kxmlgui
0078     DESCRIPTION "KXmlGui"
0079     EXPORT KXMLGUI
0080 )
0081 
0082 ki18n_wrap_ui(KF6XmlGui
0083     kshortcutsdialog.ui
0084     kshortcutwidget.ui
0085 )
0086 
0087 ecm_generate_export_header(KF6XmlGui
0088     BASE_NAME KXmlGui
0089     GROUP_BASE_NAME KF
0090     VERSION ${KF_VERSION}
0091     USE_VERSION_HEADER
0092     DEPRECATED_BASE_VERSION 0
0093     DEPRECATION_VERSIONS
0094     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0095 )
0096 
0097 target_include_directories(KF6XmlGui INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KXmlGui>")
0098 
0099 target_link_libraries(KF6XmlGui
0100 PUBLIC
0101     Qt6::Xml      #To parse the configuration (QDomDocument etc)
0102     Qt6::Widgets  #QWidget is used everywhere
0103     KF6::ConfigCore     #Reading config for ToolbarIcons, Shortcut Schemes...
0104     KF6::ConfigWidgets  #KStandardAction, KToggleAction...
0105 PRIVATE
0106     Qt6::Network        #QNetworkAccessManager in kaboutapplicationpersonmodel_p
0107     Qt6::PrintSupport   #QPrinter in kshortcutseditor
0108     Qt6::CorePrivate    #QSystemLocale in initializeLanguages
0109     KF6::CoreAddons     #KAboutData
0110     KF6::GuiAddons
0111     KF6::WidgetsAddons
0112     KF6::ItemViews           #KWidgetItemDelegate in KAboutApplicationPersonListDelegate
0113     KF6::I18n                #i18n and i18nc in many places
0114     KF6::IconThemes         #KIconLoader and KIconThemes in KToolBar
0115     KF6::IconWidgets        #KIconDialog
0116 )
0117 if (TARGET Qt6::DBus)
0118   target_link_libraries(KF6XmlGui PUBLIC Qt6::DBus) #QDBus connect to signal in KToolBar
0119 endif()
0120 
0121 ecm_generate_headers(KXmlGui_HEADERS
0122   HEADER_NAMES
0123   KAboutApplicationDialog
0124   KAboutPluginDialog
0125   KActionCategory
0126   KActionCollection
0127   KBugReport
0128   KEditToolBar
0129   KHelpMenu
0130   KKeySequenceWidget
0131   KMainWindow
0132   KShortcutsDialog
0133   KShortcutsEditor
0134   KShortcutWidget
0135   KToggleToolBarAction
0136   KToolBar
0137   KToolTipHelper
0138   KXMLGUIBuilder
0139   KXMLGUIClient
0140   KXMLGUIFactory
0141   KXmlGuiWindow
0142   KUndoActions
0143 
0144   REQUIRED_HEADERS KXmlGui_HEADERS
0145 )
0146 
0147 install(TARGETS KF6XmlGui EXPORT KF6XmlGuiTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0148 
0149 install(FILES
0150   ${CMAKE_CURRENT_BINARY_DIR}/kxmlgui_export.h
0151   ${KXmlGui_HEADERS}
0152   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KXmlGui COMPONENT Devel
0153 )
0154 
0155 if(BUILD_DESIGNERPLUGIN)
0156     add_subdirectory(designer)
0157 endif()
0158 
0159 ecm_qt_install_logging_categories(
0160     EXPORT KXMLGUI
0161     FILE kxmlgui.categories
0162     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0163 )
0164 
0165 if (BUILD_QCH)
0166     ecm_add_qch(
0167         KF6XmlGui_QCH
0168         NAME KXmlGui
0169         BASE_NAME KF6XmlGui
0170         VERSION ${KF_VERSION}
0171         ORG_DOMAIN org.kde
0172         SOURCES # using only public headers, to cover only public API
0173             ${KXmlGui_HEADERS}
0174         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0175         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0176         LINK_QCHS
0177             Qt6Xml_QCH
0178             Qt6DBus_QCH
0179             Qt6Widgets_QCH
0180             KF6Config_QCH
0181             KF6ConfigWidgets_QCH
0182         INCLUDE_DIRS
0183             ${CMAKE_CURRENT_BINARY_DIR}
0184         BLANK_MACROS
0185             KXMLGUI_EXPORT
0186             KXMLGUI_DEPRECATED_EXPORT
0187             KXMLGUI_DEPRECATED
0188             "KXMLGUI_DEPRECATED_VERSION(x, y, t)"
0189             "KXMLGUI_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0190             "KXMLGUI_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0191             "KXMLGUI_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0192         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0193         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0194         COMPONENT Devel
0195     )
0196 endif()
0197