frameworks/kxmlgui/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KXmlGui VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.115.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0015
0016 include(ECMMarkNonGuiExecutable)
0017 include(ECMSetupVersion)
0018 include(ECMGenerateHeaders)
0019 include(ECMAddQch)
0020 include(ECMGenerateExportHeader)
0021
0022 include(KDEInstallDirs)
0023 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0024 include(KDECMakeSettings)
0025 include(KDEGitCommitHooks)
0026 include(ECMQtDeclareLoggingCategory)
0027 include(ECMDeprecationSettings)
0028 include(CMakeDependentOption)
0029
0030 ecm_setup_version(PROJECT
0031                   VARIABLE_PREFIX KXMLGUI
0032                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kxmlgui_version.h"
0033                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5XmlGuiConfigVersion.cmake"
0034                   SOVERSION 5)
0035
0036 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0037
0038 option(FORCE_DISABLE_KGLOBALACCEL "Force building KXmlGui without KGlobalAccel. Doing this will break global shortcut support. [default=OFF]" OFF)
0039 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0040 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0041
0042 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0043 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0044
0045 # Dependencies
0046 set(REQUIRED_QT_VERSION 5.15.2)
0047 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets Xml Network PrintSupport)
0048 # On non-Apple UNIX DBus is required, on Apple Unix & Windows optional and it does not exist on Android
0049 if(UNIX AND NOT APPLE)
0050     if(NOT ANDROID)
0051         find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0052     endif()
0053 else()
0054     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} OPTIONAL_COMPONENTS DBus)
0055 endif()
0056
0057 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0058 find_package(KF5ItemViews ${KF_DEP_VERSION} REQUIRED)
0059 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0060 find_package(KF5ConfigWidgets ${KF_DEP_VERSION} REQUIRED)
0061 find_package(KF5GuiAddons ${KF_DEP_VERSION} REQUIRED)
0062 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0063 find_package(KF5IconThemes ${KF_DEP_VERSION} REQUIRED)
0064 find_package(KF5WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0065
0066 if (NOT FORCE_DISABLE_KGLOBALACCEL AND NOT WIN32 AND NOT APPLE AND NOT ANDROID)
0067     find_package(KF5GlobalAccel ${KF_DEP_VERSION} REQUIRED)
0068 endif()
0069 set (HAVE_GLOBALACCEL ${KF5GlobalAccel_FOUND})
0070
0071 ecm_set_disabled_deprecation_versions(
0072     QT 5.15.2
0073     KF 5.95
0074     KCOREADDONS 5.86 # KPluginMetaData::extraInformation
0075 )
0076
0077 add_definitions(-DTRANSLATION_DOMAIN=\"kxmlgui5\")
0078 ki18n_install(po)
0079
0080 # Subdirectories
0081 add_subdirectory(src)
0082 if (BUILD_TESTING)
0083     add_subdirectory(tests)
0084     add_subdirectory(autotests)
0085 endif()
0086
0087 # create a Config.cmake and a ConfigVersion.cmake file and install them
0088 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5XmlGui")
0089
0090 if (BUILD_QCH)
0091     ecm_install_qch_export(
0092         TARGETS KF5XmlGui_QCH
0093         FILE KF5XmlGuiQchTargets.cmake
0094         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0095         COMPONENT Devel
0096     )
0097     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5XmlGuiQchTargets.cmake\")")
0098 endif()
0099
0100 include(CMakePackageConfigHelpers)
0101
0102 configure_package_config_file(
0103   "${CMAKE_CURRENT_SOURCE_DIR}/KF5XmlGuiConfig.cmake.in"
0104   "${CMAKE_CURRENT_BINARY_DIR}/KF5XmlGuiConfig.cmake"
0105   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0106   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0107 )
0108
0109 install(FILES
0110   "${CMAKE_CURRENT_BINARY_DIR}/KF5XmlGuiConfig.cmake"
0111   "${CMAKE_CURRENT_BINARY_DIR}/KF5XmlGuiConfigVersion.cmake"
0112   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0113   COMPONENT Devel
0114 )
0115
0116 install(EXPORT KF5XmlGuiTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5XmlGuiTargets.cmake NAMESPACE KF5:: )
0117
0118 install(FILES
0119    ${CMAKE_CURRENT_BINARY_DIR}/kxmlgui_version.h
0120   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KXmlGui COMPONENT Devel
0121 )
0122
0123 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0124
0125 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)