platforms/xcb/CMakeLists.txt

0001 add_library(KF5WindowSystemX11Plugin MODULE)
0002
0003 target_sources(KF5WindowSystemX11Plugin PRIVATE
0004     kwindoweffects.cpp
0005     kwindowinfo.cpp
0006     kwindowshadow.cpp
0007     kwindowsystem.cpp
0008     kxerrorhandler.cpp
0009     kxutils.cpp
0010     plugin.cpp
0011 )
0012 ecm_qt_declare_logging_category(KF5WindowSystemX11Plugin
0013     HEADER kwindowsystem_xcb_debug.h
0014     IDENTIFIER LOG_KKEYSERVER_X11
0015     CATEGORY_NAME kf.windowsystem.keyserver.x11
0016     DEFAULT_SEVERITY Warning
0017 )
0018
0019 if (TARGET Qt5::X11Extras)
0020     set(_qt_x11_libs Qt5::X11Extras)
0021 elseif (TARGET Qt6::Gui)
0022     set(_qt_x11_libs Qt6::GuiPrivate) # qtx11extras_p.h
0023 endif()
0024
0025 target_link_libraries(KF5WindowSystemX11Plugin
0026     PRIVATE
0027         KF5WindowSystem
0028         XCB::XCB
0029         XCB::RES
0030         ${X11_LIBRARIES}
0031         ${X11_Xfixes_LIB}
0032         ${_qt_x11_libs}
0033 )
0034
0035 ecm_generate_headers(KWindowSystemX11_HEADERS
0036     HEADER_NAMES
0037         KSelectionOwner
0038         KSelectionWatcher
0039         KXMessages
0040         NETWM # does not match the classnames in that file...
0041
0042     REQUIRED_HEADERS
0043         KWindowSystemX11_HEADERS
0044 )
0045
0046 install(
0047     FILES
0048         ${KWindowSystemX11_HEADERS}
0049         kkeyserver_x11.h
0050         kmanagerselection.h
0051         fixx11h.h
0052     DESTINATION
0053         ${KDE_INSTALL_INCLUDEDIR_KF}/KWindowSystem
0054     COMPONENT
0055         Devel
0056 )
0057
0058 set_target_properties(
0059     KF5WindowSystemX11Plugin
0060     PROPERTIES LIBRARY_OUTPUT_DIRECTORY "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/kf${QT_MAJOR_VERSION}/kwindowsystem"
0061 )
0062
0063 install(
0064     TARGETS
0065         KF5WindowSystemX11Plugin
0066     DESTINATION
0067         ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/kwindowsystem/
0068 )