tests/kwalletd/CMakeLists.txt

0001 include_directories( ${CMAKE_CURRENT_SOURCE_DIR}/../../src/api/KWallet ) # for kwallet.h
0002 include_directories( ${CMAKE_CURRENT_BINARY_DIR}/../../src/api/KWallet )
0003
0004 include_directories( ${CMAKE_CURRENT_SOURCE_DIR}/../../src/runtime/kwalletd ) # kwalletwizard.h
0005 include_directories( ${CMAKE_CURRENT_BINARY_DIR}/../../src/runtime/kwalletd/backend ) # kwalletwizard.h
0006
0007 include(ECMMarkAsTest)
0008
0009 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Test)
0010 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0011 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0012 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0013 find_package(Gpgmepp) # provided by GpgME
0014
0015 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0016 remove_definitions(-DQT_NO_CAST_FROM_BYTEARRAY)
0017
0018 add_executable(kwalletwizardtest)
0019 set(kwalletwizardtest_ui_SRCS)
0020 qt_wrap_ui(kwalletwizardtest_ui_SRCS
0021    ../../src/runtime/kwalletd/kbetterthankdialogbase.ui
0022    ../../src/runtime/kwalletd/kwalletwizardpageexplanation.ui
0023    ../../src/runtime/kwalletd/kwalletwizardpageintro.ui
0024    ../../src/runtime/kwalletd/kwalletwizardpageoptions.ui
0025    ../../src/runtime/kwalletd/kwalletwizardpagepassword.ui
0026    ../../src/runtime/kwalletd/kwalletwizardpagegpgkey.ui
0027 )
0028
0029 if (Gpgmepp_FOUND)
0030     qt_wrap_ui(kwalletwizardtest_ui_SRCS
0031         ../../src/runtime/kwalletd/kwalletwizardpagepasswordgpg.ui)
0032 endif(Gpgmepp_FOUND)
0033
0034 target_sources(kwalletwizardtest PRIVATE
0035    kwalletwizardtest.cpp
0036    ../../src/runtime/kwalletd/kwalletwizard.cpp
0037    ${kwalletwizardtest_ui_SRCS}
0038 )
0039 ecm_mark_as_test(kwalletwizardtest)
0040 target_link_libraries(kwalletwizardtest
0041     KF6Wallet
0042     Qt6::Test
0043     KF6::CoreAddons
0044     KF6::I18n
0045     KF6::WidgetsAddons)
0046 if (Gpgmepp_FOUND)
0047     target_link_libraries(kwalletwizardtest Gpgmepp)
0048 endif(Gpgmepp_FOUND)
0049
0050 add_library(kwallettestlib STATIC kwallettest.cpp)
0051 target_link_libraries(kwallettestlib KF6Wallet Qt6::Widgets)
0052
0053 macro(kwalletd_tests)
0054   foreach(_testname ${ARGN})
0055     add_executable(${_testname} ${_testname}.cpp)
0056     ecm_mark_as_test(${_testname})
0057     target_link_libraries(${_testname}
0058         kwallettestlib
0059         KF6WalletBackend
0060         KF6Wallet
0061         Qt6::DBus
0062         Qt6::Test
0063         KF6::CoreAddons
0064         KF6::I18n)
0065   endforeach(_testname)
0066 endmacro()
0067
0068 kwalletd_tests(
0069     kwalletasync
0070     kwalletsync
0071     kwalletpath
0072     kwalletboth
0073     kwalletmany
0074     kwalletcbc
0075 )
0076
0077