kwalletd/backend/CMakeLists.txt

0001 include(CheckIncludeFiles)
0002 include(GenerateExportHeader)
0003
0004 ########### Configure checks for kwalletbackend ###############
0005
0006 check_include_files(stdint.h HAVE_STDINT_H)
0007 check_include_files(sys/bitypes.h HAVE_SYS_BITYPES_H)
0008 if (Gpgmepp_FOUND)
0009     add_definitions(-DHAVE_GPGMEPP)
0010     add_definitions(-DBOOST_NO_EXCEPTIONS)
0011 endif(Gpgmepp_FOUND)
0012
0013 configure_file (config-kwalletbackend.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kwalletbackend.h )
0014
0015 ########### kwalletbackend ###############
0016 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets DBus)
0017 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0018 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0019 find_package(KF6Notifications ${KF_DEP_VERSION} REQUIRED)
0020 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0021 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0022
0023 find_package(LibGcrypt 1.5.0 REQUIRED)
0024 set_package_properties(LibGcrypt PROPERTIES
0025                        TYPE REQUIRED
0026                        PURPOSE "kwalletd needs libgcrypt to perform PBKDF2-SHA512 hashing"
0027                       )
0028 find_package(Qca-qt6 REQUIRED 2.3.1)
0029
0030 ecm_setup_version(${KF_VERSION} VARIABLE_PREFIX KWALLETBACKEND SOVERSION 6)
0031
0032 add_library(KF6WalletBackend SHARED)
0033
0034 set_target_properties(KF6WalletBackend PROPERTIES
0035     VERSION   ${KWALLETBACKEND_VERSION}
0036     SOVERSION ${KWALLETBACKEND_SOVERSION}
0037 )
0038
0039 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/../../../api/KWallet)
0040 include_directories(${CMAKE_CURRENT_BINARY_DIR}/../../../api/KWallet)
0041 include_directories(${LIBGCRYPT_INCLUDE_DIRS})
0042
0043 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0044
0045 target_sources(KF6WalletBackend PRIVATE
0046    blockcipher.cc
0047    blowfish.cc
0048    cbc.cc
0049    sha1.cc
0050    kwalletentry.cc
0051    kwalletbackend.cc
0052    backendpersisthandler.cpp
0053 )
0054 ecm_qt_declare_logging_category(KF6WalletBackend
0055     HEADER kwalletbackend_debug.h
0056     IDENTIFIER KWALLETBACKEND_LOG
0057     CATEGORY_NAME kf.wallet.backend
0058     OLD_CATEGORY_NAMES kf5.kwallet.kwalletbackend
0059     DESCRIPTION "kwalletbackend"
0060     EXPORT KWALLET
0061 )
0062
0063
0064 generate_export_header(KF6WalletBackend
0065     BASE_NAME kwalletbackend
0066 )
0067
0068 target_link_libraries(KF6WalletBackend
0069     Qt6::Widgets
0070     KF6::WidgetsAddons
0071     KF6::CoreAddons
0072     KF6::Notifications
0073     KF6::I18n
0074     ${LIBGCRYPT_LIBRARIES}
0075     ${Qca_LIBRARY}
0076 )
0077 if(Gpgmepp_FOUND)
0078    target_link_libraries(KF6WalletBackend Gpgmepp)
0079 endif(Gpgmepp_FOUND)
0080
0081 # link with advapi32 on windows
0082 if(WIN32 AND NOT WINCE)
0083    target_link_libraries(KF6WalletBackend advapi32)
0084 endif(WIN32 AND NOT WINCE)
0085
0086 install(TARGETS KF6WalletBackend ${KF_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0087
0088 add_subdirectory(tests)