frameworks/kwallet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KWallet VERSION ${KF_VERSION})
0006 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
0007
0008 include(FeatureSummary)
0009 find_package(ECM 5.115.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://invent.kde.org/frameworks/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018
0019 include(KDEGitCommitHooks)
0020 include(ECMDeprecationSettings)
0021
0022 set(REQUIRED_QT_VERSION 5.15.2)
0023 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets DBus)
0024
0025 include(ECMAddQch)
0026 include(ECMGenerateExportHeader)
0027 include(ECMSetupVersion)
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMMarkNonGuiExecutable)
0030
0031 option(BUILD_KWALLETD "Build the kwallet daemon" ON)
0032 option(BUILD_KWALLET_QUERY "Build kwallet-query tool" ON)
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0036
0037 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0038 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0039 find_package(KF5WindowSystem ${KF_DEP_VERSION} REQUIRED)
0040 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0041 find_package(KF5DocTools ${KF_DEP_VERSION})
0042
0043 ecm_set_disabled_deprecation_versions(
0044     QT 5.15.2
0045     KF 5.95
0046     KSERVICE 5.81 # KToolInvocation::startServiceByDesktopName
0047 )
0048
0049 add_definitions(-DTRANSLATION_DOMAIN=\"kwalletd5\")
0050 ki18n_install(po)
0051 add_subdirectory(src)
0052 if (BUILD_TESTING)
0053     add_subdirectory(autotests)
0054     add_subdirectory(tests)
0055     add_subdirectory(examples)
0056 endif()
0057 if (KF5DocTools_FOUND)
0058     add_subdirectory(docs)
0059 endif()
0060
0061 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0062
0063 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)