provider/widgets/CMakeLists.txt

0001 set(userfeedback_widgets_srcs
0002     feedbackconfigdialog.cpp
0003     feedbackconfigwidget.cpp
0004     notificationpopup.cpp
0005     styleinfosource.cpp
0006     auditlogbrowserdialog.cpp
0007
0008     feedbackconfigdialog.h
0009     feedbackconfigwidget.h
0010     notificationpopup.h
0011     styleinfosource.h
0012     auditlogbrowserdialog.h
0013 )
0014
0015 add_library(KF6UserFeedbackWidgets ${userfeedback_widgets_srcs})
0016 add_library(KF6::UserFeedbackWidgets ALIAS KF6UserFeedbackWidgets)
0017
0018 set_target_properties(KF6UserFeedbackWidgets PROPERTIES
0019     SOVERSION ${KUSERFEEDBACK_SOVERSION}
0020     VERSION ${KUSERFEEDBACK_VERSION}
0021     EXPORT_NAME UserFeedbackWidgets
0022 )
0023 generate_export_header(KF6UserFeedbackWidgets BASE_NAME KUserFeedbackWidgets)
0024 target_link_libraries(KF6UserFeedbackWidgets PUBLIC Qt6::Widgets KF6UserFeedbackCore)
0025 target_include_directories(KF6UserFeedbackWidgets PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR}>")
0026 target_include_directories(KF6UserFeedbackWidgets INTERFACE
0027                            "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KUserFeedback;${KDE_INSTALL_INCLUDEDIR}>"
0028                            "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KUserFeedbackWidgets;${KDE_INSTALL_INCLUDEDIR}>"
0029                           )
0030
0031 ecm_generate_headers(KUserFeedbackWidgets_CamelCase_HEADERS
0032     HEADER_NAMES
0033         FeedbackConfigDialog
0034         FeedbackConfigWidget
0035         NotificationPopup
0036         StyleInfoSource
0037     PREFIX KUserFeedback
0038     REQUIRED_HEADERS KUserFeedbackWidgets_HEADERS
0039 )
0040
0041 install(TARGETS KF6UserFeedbackWidgets EXPORT KF6UserFeedbackTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0042 install(FILES
0043     ${CMAKE_CURRENT_BINARY_DIR}/kuserfeedbackwidgets_export.h
0044     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUserFeedbackWidgets
0045     COMPONENT Devel
0046 )
0047 install(FILES
0048     ${KUserFeedbackWidgets_HEADERS}
0049     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUserFeedbackWidgets/kuserfeedback
0050     COMPONENT Devel
0051 )
0052
0053 install(FILES
0054     ${KUserFeedbackWidgets_CamelCase_HEADERS}
0055     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUserFeedbackWidgets/KUserFeedback
0056     COMPONENT Devel
0057 )
0058
0059 ecm_generate_pri_file(BASE_NAME KF6UserFeedbackWidgets
0060                       LIB_NAME KF6UserFeedbackWidgets
0061                       DEPS "KF6UserFeedbackCore widgets"
0062                       FILENAME_VAR PRI_FILENAME
0063 )
0064
0065 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})