kuserfeedback/autotests/CMakeLists.txt

0001 configure_file(test-config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/test-config.h)
0002 if(TARGET KF6UserFeedbackConsole)
0003     add_library(KF6UserFeedbackTestUtils STATIC
0004         servercontroller.cpp servercontroller.h
0005     )
0006     target_link_libraries(KF6UserFeedbackTestUtils LINK_PUBLIC Qt6::Test KF6UserFeedbackConsole)
0007 endif()
0008
0009 function(uf_add_test _file)
0010     get_filename_component(_name ${_file} NAME_WE)
0011     add_executable(${_name} ${_file})
0012     target_link_libraries(${_name} Qt6::Test ${ARGN})
0013     add_test(NAME ${_name} COMMAND ${_name})
0014 endfunction()
0015
0016 uf_add_test(datasourcetest.cpp KF6UserFeedbackCore Qt6::Gui) # needs Gui for ScreenInfoSource to work
0017 uf_add_test(openglinfosourcetest.cpp KF6UserFeedbackCore Qt6::Gui)
0018 uf_add_test(providertest.cpp KF6UserFeedbackCore Qt6::Gui)
0019 uf_add_test(selectionratiosourcetest.cpp KF6UserFeedbackCore Qt6::Gui)
0020 uf_add_test(surveyprovidertest.cpp KF6UserFeedbackCore)
0021
0022 uf_add_test(feedbackconfigtest.cpp KF6UserFeedbackWidgets)
0023
0024 if(HAVE_SURVEY_TARGET_EXPRESSIONS)
0025     uf_add_test(surveytargetexpressiontest.cpp KF6UserFeedbackCommon)
0026 endif()
0027
0028 if(TARGET KF6UserFeedbackConsole)
0029     uf_add_test(producttest.cpp KF6UserFeedbackConsole)
0030     uf_add_test(schematemplatetest.cpp KF6UserFeedbackConsole)
0031     uf_add_test(sampletest.cpp KF6UserFeedbackConsole)
0032     uf_add_test(serverinfotest.cpp KF6UserFeedbackConsole)
0033
0034     uf_add_test(schemamodeltest.cpp KF6UserFeedbackTestUtils)
0035     uf_add_test(datamodeltest.cpp KF6UserFeedbackTestUtils)
0036     uf_add_test(timeaggregationmodeltest.cpp KF6UserFeedbackTestUtils)
0037     uf_add_test(categoryaggregationmodeltest.cpp KF6UserFeedbackTestUtils)
0038     uf_add_test(numericaggregationmodeltest.cpp KF6UserFeedbackTestUtils)
0039     uf_add_test(ratiosetaggregationmodeltest.cpp KF6UserFeedbackTestUtils)
0040 endif()
0041
0042 if(ENABLE_PHP)
0043     list(FIND PHP_MODULES "PDO" _has_pdo)
0044     if(TARGET KF6UserFeedbackConsole AND _has_pdo GREATER -1)
0045         uf_add_test(productapitest.cpp KF6UserFeedbackTestUtils)
0046         uf_add_test(productmodeltest.cpp KF6UserFeedbackTestUtils)
0047         uf_add_test(surveyapitest.cpp KF6UserFeedbackTestUtils)
0048         uf_add_test(submittest.cpp KF6UserFeedbackTestUtils KF6UserFeedbackCore Qt6::Gui)
0049     endif()
0050
0051     set(php_test_srcs
0052         utilstest.php
0053         schemaentrytest.php
0054         schemaentryelementtest.php
0055         producttest.php
0056         sampletest.php
0057         surveytest.php
0058         aggregationtest.php
0059     )
0060
0061     php_lint(datastoretesthelper.php)
0062     php_lint(${php_test_srcs})
0063     if(PhpUnit_FOUND)
0064         foreach(_php_test ${php_test_srcs})
0065             add_test(NAME ${_php_test} COMMAND ${PHPUNIT_EXECUTABLE} ${_php_test} WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
0066         endforeach()
0067     endif()
0068 endif()