kunitconversion/src/CMakeLists.txt

0001 add_library(KF5UnitConversion)
0002 add_library(KF5::UnitConversion ALIAS KF5UnitConversion)
0003
0004 ecm_qt_declare_logging_category(KF5UnitConversion
0005     HEADER kunitconversion_debug.h
0006     IDENTIFIER LOG_KUNITCONVERSION
0007     CATEGORY_NAME kf.kunitconversion
0008     DESCRIPTION "kunitconversion"
0009     EXPORT KUNITCONVERSION
0010 )
0011
0012 target_sources(KF5UnitConversion PRIVATE
0013     converter.cpp
0014     value.cpp
0015     unit.cpp
0016     unitcategory.cpp
0017     length.cpp
0018     area.cpp
0019     volume.cpp
0020     temperature.cpp
0021     velocity.cpp
0022     mass.cpp
0023     pressure.cpp
0024     energy.cpp
0025     currency.cpp
0026     power.cpp
0027     timeunit.cpp
0028     fuel_efficiency.cpp
0029     density.cpp
0030     acceleration.cpp
0031     force.cpp
0032     angle.cpp
0033     frequency.cpp
0034     thermal_conductivity.cpp
0035     thermal_flux.cpp
0036     thermal_generation.cpp
0037     voltage.cpp
0038     electrical_current.cpp
0039     electrical_resistance.cpp
0040     permeability.cpp
0041     binary_data.cpp
0042 )
0043
0044 if (WIN32)
0045     # As stated in http://msdn.microsoft.com/en-us/library/4hwaceh6.aspx M_PI only gets defined
0046     # when using MSVC if _USE_MATH_DEFINES is defined (this is needed for angle.cpp)
0047     target_compile_definitions(KF5UnitConversion PRIVATE _USE_MATH_DEFINES)
0048 endif()
0049 ecm_generate_export_header(KF5UnitConversion
0050     BASE_NAME KUnitConversion
0051     EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kunitconversion/kunitconversion_export.h
0052     GROUP_BASE_NAME KF
0053     VERSION ${KF_VERSION}
0054     DEPRECATED_BASE_VERSION 0
0055     DEPRECATION_VERSIONS 5.91
0056     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0057 )
0058
0059 set(kunitconversion_BUILD_INCLUDE_DIRS ${KUnitConversion_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR})
0060 target_include_directories(KF5UnitConversion PUBLIC "$<BUILD_INTERFACE:${kunitconversion_BUILD_INCLUDE_DIRS}>")
0061 target_include_directories(KF5UnitConversion INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KUnitConversion>")
0062
0063 target_link_libraries(KF5UnitConversion PUBLIC  Qt${QT_MAJOR_VERSION}::Core
0064                                         PRIVATE Qt${QT_MAJOR_VERSION}::Network
0065                                                 KF5::I18n
0066 )
0067
0068 set_target_properties(KF5UnitConversion PROPERTIES VERSION   ${KUNITCONVERSION_VERSION}
0069                                                    SOVERSION ${KUNITCONVERSION_SOVERSION}
0070                                                    EXPORT_NAME UnitConversion
0071 )
0072
0073 ecm_generate_headers(KUnitConversion_CamelCase_HEADERS
0074     HEADER_NAMES
0075     Converter
0076     Value
0077     Unit
0078     UnitCategory
0079
0080     PREFIX KUnitConversion
0081     REQUIRED_HEADERS KUnitConversion_HEADERS
0082 )
0083 install(FILES ${KUnitConversion_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUnitConversion/KUnitConversion COMPONENT Devel)
0084
0085 install(TARGETS KF5UnitConversion EXPORT KF5UnitConversionTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0086 install(FILES
0087     ${CMAKE_CURRENT_BINARY_DIR}/kunitconversion/kunitconversion_export.h
0088     ${KUnitConversion_HEADERS}
0089     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUnitConversion/kunitconversion COMPONENT Devel
0090 )
0091
0092 ecm_qt_install_logging_categories(
0093     EXPORT KUNITCONVERSION
0094     FILE kunitconversion.categories
0095     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0096 )
0097
0098 if(BUILD_QCH)
0099     ecm_add_qch(
0100         KF5UnitConversion_QCH
0101         NAME KUnitConversion
0102         BASE_NAME KF5UnitConversion
0103         VERSION ${KF_VERSION}
0104         ORG_DOMAIN org.kde
0105         SOURCES # using only public headers, to cover only public API
0106             ${KUnitConversion_HEADERS}
0107         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0108         LINK_QCHS
0109             Qt5Core_QCH
0110         INCLUDE_DIRS
0111             ${kunitconversion_BUILD_INCLUDE_DIRS}
0112         BLANK_MACROS
0113             KUNITCONVERSION_EXPORT
0114             KUNITCONVERSION_DEPRECATED
0115             KUNITCONVERSION_DEPRECATED_EXPORT
0116         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0117         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0118         COMPONENT Devel
0119     )
0120 endif()
0121
0122 include(ECMGeneratePriFile)
0123 ecm_generate_pri_file(BASE_NAME KUnitConversion LIB_NAME KF5UnitConversion DEPS "core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KUnitConversion)
0124 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})