frameworks/kunitconversion/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0005 project(KUnitConversion VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.106.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0011
0012 include(KDEInstallDirs)
0013 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0014 include(KDECMakeSettings)
0015 include(ECMGenerateExportHeader)
0016 include(ECMSetupVersion)
0017 include(ECMGenerateHeaders)
0018 include(ECMQtDeclareLoggingCategory)
0019 include(ECMDeprecationSettings)
0020
0021 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0022
0023 set(REQUIRED_QT_VERSION 5.15.2)
0024 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Network)
0025
0026 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5UnitConversion")
0027
0028 ecm_setup_version(PROJECT VARIABLE_PREFIX KUNITCONVERSION
0029                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kunitconversion_version.h"
0030                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5UnitConversionConfigVersion.cmake"
0031                         SOVERSION 5)
0032
0033 # QCH
0034 include(ECMAddQch)
0035 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0036 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0037 if (BUILD_QCH)
0038     ecm_install_qch_export(
0039         TARGETS KF5UnitConversion_QCH
0040         FILE KF5UnitConversionQchTargets.cmake
0041         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0042         COMPONENT Devel
0043     )
0044     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5UnitConversionQchTargets.cmake\")")
0045 endif()
0046
0047 # I18n
0048 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0049 add_definitions(-DTRANSLATION_DOMAIN=\"kunitconversion5\")
0050 ki18n_install(po)
0051
0052 ecm_set_disabled_deprecation_versions(
0053     QT 5.15.2
0054     KF 5.97
0055 )
0056
0057 add_subdirectory(src)
0058 if (BUILD_TESTING)
0059     add_subdirectory(autotests)
0060 endif()
0061 # create a Config.cmake and a ConfigVersion.cmake file and install them
0062 include(CMakePackageConfigHelpers)
0063 configure_package_config_file(
0064     "${CMAKE_CURRENT_SOURCE_DIR}/KF5UnitConversionConfig.cmake.in"
0065     "${CMAKE_CURRENT_BINARY_DIR}/KF5UnitConversionConfig.cmake"
0066     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0067 )
0068 install(FILES
0069     "${CMAKE_CURRENT_BINARY_DIR}/KF5UnitConversionConfig.cmake"
0070     "${CMAKE_CURRENT_BINARY_DIR}/KF5UnitConversionConfigVersion.cmake"
0071     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072     COMPONENT Devel
0073 )
0074 install(EXPORT KF5UnitConversionTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5UnitConversionTargets.cmake NAMESPACE KF5:: )
0075 install(FILES
0076     ${CMAKE_CURRENT_BINARY_DIR}/kunitconversion_version.h
0077     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KUnitConversion COMPONENT Devel
0078 )
0079
0080 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)