frameworks/ktextwidgets/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KTextWidgets VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.115.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019
0020 include(ECMGenerateExportHeader)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(CMakePackageConfigHelpers)
0024 include(ECMAddQch)
0025 include(ECMDeprecationSettings)
0026 include(CMakeDependentOption)
0027
0028 ecm_setup_version(PROJECT
0029                   VARIABLE_PREFIX KTEXTWIDGETS
0030                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/ktextwidgets_version.h"
0031                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5TextWidgetsConfigVersion.cmake"
0032                   SOVERSION 5)
0033
0034 # Dependencies
0035 set(REQUIRED_QT_VERSION 5.15.2)
0036
0037 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0038
0039 # No QTextToSpeech in Qt6.2
0040 if (QT_MAJOR_VERSION STREQUAL "5")
0041     find_package(Qt5 OPTIONAL_COMPONENTS TextToSpeech)
0042 endif()
0043 if (NOT Qt5TextToSpeech_FOUND)
0044     message(STATUS "Qt5TextToSpeech not found, speech feature will be disabled")
0045 else()
0046     add_definitions(-DHAVE_SPEECH)
0047 endif()
0048
0049 find_package(KF5Completion ${KF_DEP_VERSION} REQUIRED)
0050 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0051 find_package(KF5ConfigWidgets ${KF_DEP_VERSION} REQUIRED)
0052 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0053 find_package(KF5WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0054 find_package(KF5Sonnet ${KF_DEP_VERSION} REQUIRED)
0055
0056 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0057
0058 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0059 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0060
0061 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0062 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0063
0064 add_definitions(-DTRANSLATION_DOMAIN=\"ktextwidgets5\")
0065
0066 ecm_set_disabled_deprecation_versions(
0067     QT 5.15.2
0068     KF 5.95
0069 )
0070
0071 ki18n_install(po)
0072 add_subdirectory(src)
0073 if (BUILD_TESTING)
0074     add_subdirectory(tests)
0075     add_subdirectory(autotests)
0076 endif()
0077
0078 # create a Config.cmake and a ConfigVersion.cmake file and install them
0079 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5TextWidgets")
0080
0081 if (BUILD_QCH)
0082     ecm_install_qch_export(
0083         TARGETS KF5TextWidgets_QCH
0084         FILE KF5TextWidgetsQchTargets.cmake
0085         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0086         COMPONENT Devel
0087     )
0088     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5TextWidgetsQchTargets.cmake\")")
0089 endif()
0090
0091 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5TextWidgetsConfig.cmake.in"
0092                               "${CMAKE_CURRENT_BINARY_DIR}/KF5TextWidgetsConfig.cmake"
0093                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0094                              )
0095
0096 install(EXPORT KF5TextWidgetsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5TextWidgetsTargets.cmake NAMESPACE KF5:: )
0097
0098 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/KF5TextWidgetsConfig.cmake"
0099               "${CMAKE_CURRENT_BINARY_DIR}/KF5TextWidgetsConfigVersion.cmake"
0100         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101         COMPONENT Devel
0102        )
0103
0104 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/ktextwidgets_version.h
0105         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets COMPONENT Devel
0106        )
0107
0108 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0109
0110 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)