ktexttemplate/autotests/CMakeLists.txt

0001 find_package(Qt6Test ${REQUIRED_QT_VERSION} REQUIRED)
0002
0003 set( EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_BINARY_DIR} )
0004
0005 set( KTEXTTEMPLATE_PLUGIN_PATH "${CMAKE_BINARY_DIR}/" )
0006
0007 configure_file(ktexttemplate_paths.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/ktexttemplate_paths.h)
0008
0009 find_package(Qt6LinguistTools QUIET)
0010 if (Qt6LinguistTools_FOUND)
0011   set(TESTS_LOCALES "fr_FR" "de_DE")
0012
0013   set(QT_LUPDATE_EXECUTABLE Qt6::lupdate)
0014   set(QT_LRELEASE_EXECUTABLE Qt6::lrelease)
0015
0016   set(LINGUIST_TS_ARGS COMMAND "${QT_LUPDATE_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/test_input.cpp" "-ts")
0017
0018   foreach(TESTS_LOCALE ${TESTS_LOCALES})
0019       set( LINGUIST_TS_ARGS ${LINGUIST_TS_ARGS} "${CMAKE_CURRENT_SOURCE_DIR}/test_${TESTS_LOCALE}.ts" )
0020   endforeach()
0021
0022   add_custom_target(test_l10n
0023     ${LINGUIST_TS_ARGS}
0024   )
0025
0026   set( LINGUIST_QM_ARGS COMMAND "${QT_LRELEASE_EXECUTABLE}" )
0027
0028   set( generate_QMs )
0029   foreach(TESTS_LOCALE ${TESTS_LOCALES})
0030       set( generate_QMs ${generate_QMs} ${LINGUIST_QM_ARGS} "${CMAKE_CURRENT_SOURCE_DIR}/test_${TESTS_LOCALE}.ts" "-qm" "${CMAKE_CURRENT_BINARY_DIR}/test_${TESTS_LOCALE}.qm" )
0031   endforeach()
0032
0033   add_custom_command(
0034     OUTPUT test_de_DE.qm test_fr_FR.qm
0035     ${generate_QMs}
0036     DEPENDS test_de_DE.ts test_fr_FR.ts
0037   )
0038
0039   set(QM_FILES "
0040 <qresource>
0041     <file alias=\"test_de_DE.qm\">${CMAKE_CURRENT_BINARY_DIR}/test_de_DE.qm</file>
0042     <file alias=\"test_fr_FR.qm\">${CMAKE_CURRENT_BINARY_DIR}/test_fr_FR.qm</file>
0043 </qresource>")
0044 endif()
0045
0046 configure_file(testresource.qrc.cmake "${CMAKE_CURRENT_BINARY_DIR}/testresource.qrc")
0047
0048 set (_rcc_file "${CMAKE_CURRENT_BINARY_DIR}/testresource.qrc")
0049
0050 qt6_add_resources(_testresource_rcc_src ${_rcc_file} OPTIONS -root "/" )
0051
0052 add_library(template_test_builtins STATIC
0053   ${_testresource_rcc_src}
0054 )
0055 target_link_libraries(template_test_builtins Qt6::Test)
0056
0057 macro(ktexttemplate_templates_unit_tests)
0058   foreach(_testname ${ARGN})
0059     add_executable(${_testname}_exec
0060                   ${_testname}.cpp
0061     )
0062     add_test(${_testname} ${CMAKE_BINARY_DIR}/bin/${_testname}_exec )
0063     target_link_libraries(${_testname}_exec KF6::TextTemplate template_test_builtins)
0064
0065     if (Qt6Qml_FOUND)
0066       target_compile_definitions(${_testname}_exec PRIVATE HAVE_QTQML_LIB)
0067     endif()
0068   endforeach(_testname)
0069 endmacro()
0070
0071 ktexttemplate_templates_unit_tests(
0072   testsafestring
0073   testbuiltins
0074   testloadertags
0075   testdefaulttags
0076   testcachingloader
0077   testfilters
0078   testgenerictypes
0079   testgenericcontainers
0080 )
0081
0082 if (Qt6Qml_FOUND)
0083   ktexttemplate_templates_unit_tests(
0084     testscriptabletags
0085   )
0086 endif()
0087
0088 if (Qt6LinguistTools_FOUND)
0089   ktexttemplate_templates_unit_tests(
0090     testinternationalization
0091   )
0092   if ("x${CMAKE_CXX_COMPILER_ID}x" MATCHES "xMSVCx")
0093     target_compile_options(testinternationalization_exec PRIVATE "/utf-8")
0094   endif()
0095 endif()