frameworks/kservice/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KService VERSION ${KF_VERSION})
0006
0007 # Disallow in-source build
0008 if("${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_BINARY_DIR}")
0009    message(FATAL_ERROR "KService requires an out of source build. Please create a separate build directory and run 'cmake path_to_kservice [options]' there.")
0010 endif()
0011
0012 # ECM setup
0013 include(FeatureSummary)
0014 find_package(ECM 5.249.0  NO_MODULE)
0015 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0016 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0017
0018 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0019
0020 include(KDEInstallDirs)
0021 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0022 include(KDECMakeSettings)
0023 include(KDEGitCommitHooks)
0024 include(ECMSetupVersion)
0025 include(ECMGenerateHeaders)
0026 include(ECMAddQch)
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMGenerateExportHeader)
0029 include(ECMDeprecationSettings)
0030
0031 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 set(kservice_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kservice_version.h")
0037 ecm_setup_version(PROJECT
0038                   VARIABLE_PREFIX KSERVICE
0039                   VERSION_HEADER "${kservice_version_header}"
0040                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ServiceConfigVersion.cmake"
0041                   SOVERSION 6)
0042
0043 # Dependencies
0044 set(REQUIRED_QT_VERSION 6.5.0)
0045 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Xml)
0046
0047 find_package(KF6Config ${KF_DEP_VERSION} CONFIG REQUIRED)
0048 find_package(KF6CoreAddons ${KF_DEP_VERSION} CONFIG REQUIRED)
0049 find_package(KF6I18n ${KF_DEP_VERSION} CONFIG REQUIRED)
0050 find_package(KF6DocTools ${KF_DEP_VERSION} CONFIG)
0051
0052 add_definitions(-DTRANSLATION_DOMAIN=\"kservice6\")
0053
0054 ecm_set_disabled_deprecation_versions(
0055     QT 6.5
0056     KF 5.102.0
0057 )
0058
0059 ki18n_install(po)
0060
0061 if (KF6DocTools_FOUND)
0062     kdoctools_install(po)
0063 endif()
0064
0065 if (KF6DocTools_FOUND)
0066     add_subdirectory(docs)
0067 endif()
0068
0069 add_subdirectory(src)
0070 if (BUILD_TESTING)
0071     add_subdirectory(autotests)
0072     add_subdirectory(tests)
0073 endif()
0074
0075 # create a Config.cmake and a ConfigVersion.cmake file and install them
0076 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Service")
0077
0078 if (BUILD_QCH)
0079     ecm_install_qch_export(
0080         TARGETS KF6Service_QCH
0081         FILE KF6ServiceQchTargets.cmake
0082         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0083         COMPONENT Devel
0084     )
0085     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ServiceQchTargets.cmake\")")
0086 endif()
0087
0088 include(CMakePackageConfigHelpers)
0089
0090 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6ServiceConfig.cmake.in"
0091                               "${CMAKE_CURRENT_BINARY_DIR}/KF6ServiceConfig.cmake"
0092                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0093                              )
0094
0095 install(EXPORT KF6ServiceTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ServiceTargets.cmake NAMESPACE KF6:: )
0096
0097 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/KF6ServiceConfig.cmake"
0098               "${CMAKE_CURRENT_BINARY_DIR}/KF6ServiceConfigVersion.cmake"
0099         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0100         COMPONENT Devel
0101        )
0102
0103 install(FILES ${kservice_version_header}
0104         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KService COMPONENT Devel)
0105
0106 include(ECMFeatureSummary)
0107 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0108
0109 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)