krunner/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: KDE Contributors
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 add_library(KF6Runner SHARED)
0005 add_library(KF6::Runner ALIAS KF6Runner)
0006
0007 set_target_properties(KF6Runner PROPERTIES
0008     VERSION     ${KRUNNER_VERSION}
0009     SOVERSION   ${KRUNNER_SOVERSION}
0010     EXPORT_NAME Runner
0011 )
0012
0013 target_sources(KF6Runner PRIVATE
0014     abstractrunner.cpp
0015     abstractrunner.h
0016     abstractrunnertest.h
0017     dbusrunner.cpp
0018     dbusrunner_p.h
0019     dbusutils_p.h
0020     querymatch.cpp
0021     querymatch.h
0022     runnercontext.cpp
0023     runnercontext.h
0024     runnermanager.cpp
0025     runnermanager.h
0026     runnersyntax.cpp
0027     runnersyntax.h
0028     action.h
0029     action.cpp
0030
0031     model/runnerresultsmodel.cpp
0032     model/runnerresultsmodel_p.h
0033     model/resultsmodel.cpp
0034     model/resultsmodel.h
0035 )
0036 ecm_qt_declare_logging_category(KF6Runner
0037     HEADER krunner_debug.h
0038     IDENTIFIER KRUNNER
0039     CATEGORY_NAME kf.runner
0040     OLD_CATEGORY_NAMES org.kde.krunner
0041     DESCRIPTION "KRunner"
0042     EXPORT KRUNNER
0043 )
0044 set_property(SOURCE "data/org.kde.krunner1.xml" PROPERTY INCLUDE dbusutils_p.h)
0045
0046 ecm_generate_export_header(KF6Runner
0047     BASE_NAME KRunner
0048     GROUP_BASE_NAME KF
0049     VERSION ${KF_VERSION}
0050     USE_VERSION_HEADER
0051     DEPRECATED_BASE_VERSION 0
0052     DEPRECATION_VERSIONS
0053     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0054 )
0055
0056 set(KRunner_BUILD_INCLUDE_DIRS ${KRunner_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR})
0057 target_include_directories(KF6Runner INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KRunner>")
0058 target_include_directories(KF6Runner PUBLIC "$<BUILD_INTERFACE:${KRunner_BUILD_INCLUDE_DIRS}>")
0059
0060
0061 target_link_libraries(KF6Runner
0062     PUBLIC
0063         Qt6::Core
0064         KF6::CoreAddons # KPluginFactory
0065     PRIVATE
0066         Qt6::DBus
0067         Qt6::Gui
0068         KF6::ConfigCore
0069         KF6::I18n
0070         KF6::ItemModels
0071 )
0072 ecm_generate_headers(KRunner_CamelCase_HEADERS
0073   HEADER_NAMES
0074     AbstractRunner
0075     Action
0076     RunnerContext
0077     RunnerManager
0078     RunnerSyntax
0079     QueryMatch
0080     AbstractRunnerTest
0081
0082     PREFIX KRunner
0083     REQUIRED_HEADERS KRunner_HEADERS
0084 )
0085 ecm_generate_headers(KRunner_CamelCase_HEADERS
0086   HEADER_NAMES ResultsModel
0087     PREFIX KRunner
0088     REQUIRED_HEADERS KRunner_HEADERS
0089     RELATIVE model
0090 )
0091
0092 # Install files
0093
0094 install(TARGETS KF6Runner
0095         EXPORT KF6RunnerTargets
0096         ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0097
0098 install(FILES ${KRunner_CamelCase_HEADERS}
0099         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KRunner/KRunner
0100         COMPONENT Devel)
0101
0102 install(FILES
0103             ${CMAKE_CURRENT_BINARY_DIR}/krunner_export.h
0104             ${KRunner_HEADERS}
0105         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KRunner/krunner
0106         COMPONENT Devel)
0107
0108 ecm_qt_install_logging_categories(
0109     EXPORT KRUNNER
0110     FILE krunner.categories
0111     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0112 )
0113
0114
0115 if(BUILD_QCH)
0116     ecm_add_qch(
0117         KF6Runner_QCH
0118         NAME KRunner
0119         BASE_NAME KF6Runner
0120         VERSION ${KF_VERSION}
0121         ORG_DOMAIN org.kde
0122         SOURCES # using only public headers, to cover only public API
0123             ${KRunner_HEADERS}
0124         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0125         LINK_QCHS
0126             Qt6Core_QCH
0127             KF6CoreAddons_QCH
0128         INCLUDE_DIRS
0129             ${KRunner_BUILD_INCLUDE_DIRS}
0130         BLANK_MACROS
0131             KRUNNER_EXPORT
0132             KRUNNER_DEPRECATED
0133             KRUNNER_DEPRECATED_EXPORT
0134             "KRUNNER_DEPRECATED_VERSION(x, y, t)"
0135             "KRUNNER_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0136             "KRUNNER_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0137         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0138         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0139         COMPONENT Devel
0140     )
0141 endif()
0142
0143 install(FILES
0144    "data/org.kde.krunner1.xml"
0145    DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0146    RENAME kf6_org.kde.krunner1.xml)