src/core/CMakeLists.txt

0001
0002 file(GLOB _KROSSCOREHEADERS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.h)
0003 #message(STATUS _KROSSCOREHEADERS=${_KROSSCOREHEADERS})
0004 foreach(_KROSSCOREHEADER ${_KROSSCOREHEADERS})
0005     string(REGEX MATCH ".*_p\\.h" _ISPRIVATE ${_KROSSCOREHEADER})
0006     #message(STATUS "_ISPRIVATE=${_ISPRIVATE} _KROSSCOREHEADER=${_KROSSCOREHEADER}")
0007     if (NOT _ISPRIVATE)
0008         if (NOT EXISTS ${_INCDIR}/core/${_KROSSCOREHEADER})
0009             file(WRITE ${_INCDIR}/core/${_KROSSCOREHEADER} "#include \"${CMAKE_CURRENT_SOURCE_DIR}/${_KROSSCOREHEADER}\"\n")
0010         endif()
0011     endif()
0012 endforeach()
0013 if (NOT EXISTS ${_INCDIR}/core/krosscore_export.h)
0014     file(WRITE ${_INCDIR}/core/krosscore_export.h "#include \"${CMAKE_CURRENT_BINARY_DIR}/krosscore_export.h\"\n")
0015 endif()
0016
0017 add_library(KF5KrossCore)
0018 add_library(KF5::KrossCore ALIAS KF5KrossCore)
0019
0020 target_sources(KF5KrossCore PRIVATE
0021    krossconfig.cpp
0022    interpreter.cpp
0023    script.cpp
0024    action.cpp
0025    actioncollection.cpp
0026    manager.cpp
0027    metafunction.cpp
0028    object.cpp
0029 )
0030
0031 ecm_qt_declare_logging_category(KF5KrossCore
0032     HEADER kross_debug.h
0033     IDENTIFIER KROSS_LOG
0034     CATEGORY_NAME kf.kross.core
0035 )
0036
0037 ecm_generate_export_header(KF5KrossCore
0038     BASE_NAME KrossCore
0039     GROUP_BASE_NAME KF
0040     VERSION ${KF_VERSION}
0041     DEPRECATION_VERSIONS 5.88
0042 )
0043
0044
0045 target_include_directories(KF5KrossCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KrossCore>")
0046
0047 target_link_libraries(KF5KrossCore
0048 PUBLIC
0049    Qt5::Script
0050    Qt5::Xml
0051 PRIVATE
0052    Qt5::Widgets
0053    KF5::I18n
0054 )
0055
0056 target_include_directories(KF5KrossCore PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/../include>")
0057
0058 set_target_properties(KF5KrossCore PROPERTIES VERSION ${KROSS_VERSION}
0059                                    SOVERSION ${KROSS_SOVERSION}
0060                                    EXPORT_NAME KrossCore
0061                      )
0062
0063
0064 ecm_generate_headers(KrossCore_CamelCase_HEADERS
0065   HEADER_NAMES
0066   ErrorInterface
0067   ChildrenInterface
0068   WrapperInterface
0069   Interpreter
0070   Script
0071   Action
0072   ActionCollection
0073   Manager
0074   Object
0075   MetaType
0076   MetaFunction
0077   KrossConfig
0078
0079   PREFIX Kross/Core
0080   REQUIRED_HEADERS KrossCore_HEADERS
0081 )
0082 # apps include <Kross/Core/Object> or <kross/core/object.h>
0083 install(FILES ${KrossCore_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KrossCore/Kross/Core COMPONENT Devel)
0084
0085 install(FILES
0086   ${CMAKE_CURRENT_BINARY_DIR}/krosscore_export.h
0087   ${KrossCore_HEADERS}
0088   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KrossCore/kross/core COMPONENT Devel) # apps include <kross/core/object.h>
0089
0090 install(TARGETS KF5KrossCore EXPORT KF5KrossTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
0091
0092 include(ECMGeneratePriFile)
0093 ecm_generate_pri_file(BASE_NAME KrossCore LIB_NAME KF5KrossCore DEPS "script xml" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KrossCore)
0094 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})