kquickcharts/src/CMakeLists.txt

0001
0002 add_library(QuickChartsStatic STATIC)
0003 set_target_properties(QuickChartsStatic PROPERTIES POSITION_INDEPENDENT_CODE ON)
0004
0005 target_sources(QuickChartsStatic PRIVATE
0006     BarChart.cpp
0007     BarChart.h
0008     Chart.cpp
0009     Chart.h
0010     datasource/ArraySource.cpp
0011     datasource/ArraySource.h
0012     datasource/ChartAxisSource.cpp
0013     datasource/ChartAxisSource.h
0014     datasource/ChartDataSource.cpp
0015     datasource/ChartDataSource.h
0016     datasource/ColorGradientSource.cpp
0017     datasource/ColorGradientSource.h
0018     datasource/HistoryProxySource.cpp
0019     datasource/HistoryProxySource.h
0020     datasource/MapProxySource.cpp
0021     datasource/MapProxySource.h
0022     datasource/ModelSource.cpp
0023     datasource/ModelSource.h
0024     datasource/SingleValueSource.cpp
0025     datasource/SingleValueSource.h
0026     decorations/AxisLabels.cpp
0027     decorations/AxisLabels.h
0028     decorations/GridLines.cpp
0029     decorations/GridLines.h
0030     decorations/LegendLayout.cpp
0031     decorations/LegendLayout.h
0032     decorations/LegendModel.cpp
0033     decorations/LegendModel.h
0034     ItemBuilder.cpp
0035     ItemBuilder.h
0036     LineChart.cpp
0037     LineChart.h
0038     PieChart.cpp
0039     PieChart.h
0040     RangeGroup.cpp
0041     RangeGroup.h
0042     scenegraph/BarChartMaterial.cpp
0043     scenegraph/BarChartMaterial.h
0044     scenegraph/BarChartNode.cpp
0045     scenegraph/BarChartNode.h
0046     scenegraph/LineChartMaterial.cpp
0047     scenegraph/LineChartMaterial.h
0048     scenegraph/LineChartNode.cpp
0049     scenegraph/LineChartNode.h
0050     scenegraph/LineGridNode.cpp
0051     scenegraph/LineGridNode.h
0052     scenegraph/LineSegmentNode.cpp
0053     scenegraph/LineSegmentNode.h
0054     scenegraph/PieChartMaterial.cpp
0055     scenegraph/PieChartMaterial.h
0056     scenegraph/PieChartNode.cpp
0057     scenegraph/PieChartNode.h
0058     scenegraph/SDFShader.cpp
0059     scenegraph/SDFShader.h
0060     XYChart.cpp
0061     XYChart.h
0062 )
0063
0064 ecm_qt_declare_logging_category(QuickChartsStatic
0065     HEADER charts_general_logging.h
0066     IDENTIFIER GENERAL
0067     CATEGORY_NAME kf.quickcharts.general
0068     DEFAULT_SEVERITY Warning
0069     DESCRIPTION "KQuickCharts Library - General"
0070     EXPORT KQuickCharts
0071 )
0072
0073 ecm_qt_declare_logging_category(QuickChartsStatic
0074     HEADER charts_datasource_logging.h
0075     IDENTIFIER DATASOURCE
0076     CATEGORY_NAME kf.quickcharts.datasource
0077     DEFAULT_SEVERITY Warning
0078     DESCRIPTION "KQuickCharts Library - Data Sources"
0079     EXPORT KQuickCharts
0080 )
0081
0082 ecm_qt_declare_logging_category(QuickChartsStatic
0083     HEADER charts_deprecated_logging.h
0084     IDENTIFIER DEPRECATED
0085     CATEGORY_NAME kf.quickcharts.deprecated
0086     DEFAULT_SEVERITY Warning
0087     DESCRIPTION "KQuickCharts Library - Deprecated API"
0088     EXPORT KQuickCharts
0089 )
0090
0091 target_link_libraries(QuickChartsStatic PUBLIC
0092     Qt6::Core
0093     Qt6::Quick
0094     Qt6::Qml
0095     Qt6::Quick
0096 )
0097
0098 ecm_add_qml_module(QuickCharts URI "org.kde.quickcharts" CLASSNAME QuickChartsPlugin)
0099
0100 target_sources(QuickCharts PRIVATE ChartsPlugin.cpp ChartsPlugin.h)
0101 target_link_libraries(QuickCharts PRIVATE QuickChartsStatic)
0102
0103 if (CMAKE_BUILD_TYPE STREQUAL "Debug")
0104     set(_extra_args DEBUGINFO)
0105 else()
0106     set(_extra_args OPTIMIZED)
0107 endif()
0108
0109 qt6_add_shaders(QuickCharts "shaders"
0110     BATCHABLE
0111     ZORDER_LOC 6
0112     PRECOMPILE
0113     PREFIX "/org.kde.quickcharts/"
0114     GLSL "300es,130"
0115     FILES
0116         shaders/barchart.vert
0117         shaders/barchart.frag
0118         shaders/linechart.vert
0119         shaders/linechart.frag
0120         shaders/piechart.vert
0121         shaders/piechart.frag
0122     OUTPUTS
0123         barchart.vert.qsb
0124         barchart.frag.qsb
0125         linechart.vert.qsb
0126         linechart.frag.qsb
0127         piechart.vert.qsb
0128         piechart.frag.qsb
0129     ${_extra_args}
0130 )
0131
0132 ecm_generate_export_header(QuickCharts
0133     BASE_NAME QuickCharts
0134     GROUP_BASE_NAME KF
0135     VERSION ${KF_VERSION}
0136     DEPRECATED_BASE_VERSION 0
0137     DEPRECATION_VERSIONS
0138     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0139 )
0140
0141 ecm_finalize_qml_module(QuickCharts DESTINATION ${KDE_INSTALL_QMLDIR})
0142
0143 ecm_qt_install_logging_categories(EXPORT KQuickCharts DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})