kpty/src/CMakeLists.txt

0001 add_library(KF5Pty)
0002 add_library(KF5::Pty ALIAS KF5Pty)
0003
0004 target_sources(KF5Pty PRIVATE
0005     kpty.cpp
0006     kptydevice.cpp
0007     kptydevice.h
0008     kpty.h
0009     kpty_p.h
0010     kptyprocess.cpp
0011     kptyprocess.h
0012 )
0013
0014 ecm_qt_declare_logging_category(KF5Pty
0015     HEADER kpty_debug.h
0016     IDENTIFIER KPTY_LOG
0017     CATEGORY_NAME kf.pty
0018     DESCRIPTION "KPty"
0019     EXPORT KPTY
0020 )
0021
0022 generate_export_header(KF5Pty BASE_NAME KPty)
0023
0024 include(ConfigureChecks.cmake)
0025 configure_file(config-pty.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-pty.h )
0026
0027 target_include_directories(KF5Pty INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPty>")
0028
0029 target_link_libraries(KF5Pty PUBLIC Qt${QT_MAJOR_VERSION}::Core
0030                                     KF5::CoreAddons # KProcess
0031                              PRIVATE
0032                                     ${UTIL_LIBRARY}
0033                                     KF5::I18n)
0034
0035 target_include_directories(KF5Pty PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/..)
0036 if(UTEMPTER_FOUND)
0037   target_compile_definitions(KF5Pty PRIVATE ${UTEMPTER_COMPILE_FLAGS})
0038 endif()
0039
0040 set_target_properties(KF5Pty PROPERTIES
0041    VERSION ${KPTY_VERSION}
0042    SOVERSION ${KPTY_SOVERSION}
0043    EXPORT_NAME Pty
0044 )
0045
0046 ecm_generate_headers(KPty_HEADERS
0047   HEADER_NAMES
0048   KPty
0049   KPtyDevice
0050   KPtyProcess
0051
0052   REQUIRED_HEADERS KPty_HEADERS
0053 )
0054
0055 install(TARGETS KF5Pty EXPORT KF5PtyTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0056
0057 install(FILES
0058   ${CMAKE_CURRENT_BINARY_DIR}/kpty_export.h
0059   ${KPty_HEADERS}
0060   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPty COMPONENT Devel
0061 )
0062
0063 if(BUILD_QCH)
0064     ecm_add_qch(
0065         KF5Pty_QCH
0066         NAME KPty
0067         BASE_NAME KF5Pty
0068         VERSION ${KF_VERSION}
0069         ORG_DOMAIN org.kde
0070         SOURCES # using only public headers, to cover only public API
0071             ${KPty_HEADERS}
0072         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0073         LINK_QCHS
0074             Qt5Core_QCH
0075             KF5CoreAddons_QCH
0076         INCLUDE_DIRS
0077             ${CMAKE_CURRENT_BINARY_DIR}
0078         BLANK_MACROS
0079             KPTY_EXPORT
0080             KPTY_DEPRECATED
0081             KPTY_DEPRECATED_EXPORT
0082         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0083         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0084         COMPONENT Devel
0085     )
0086 endif()
0087
0088 ########### next target ###############
0089
0090 if (NOT HAVE_OPENPTY)
0091    add_executable(kgrantpty kgrantpty.c)
0092    ecm_mark_nongui_executable(kgrantpty)
0093    install(TARGETS kgrantpty DESTINATION ${KDE_INSTALL_LIBEXECDIR_KF})
0094 endif ()
0095
0096 include(ECMGeneratePriFile)
0097 ecm_generate_pri_file(BASE_NAME KPty LIB_NAME KF5Pty DEPS "core KCoreAddons" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KPty)
0098 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0099
0100 ecm_qt_install_logging_categories(
0101     EXPORT KPTY
0102     FILE kpty.categories
0103     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0104 )