kplotting/src/CMakeLists.txt

0001 add_library(KF5Plotting)
0002 add_library(KF5::Plotting ALIAS KF5Plotting)
0003
0004 target_sources(KF5Plotting PRIVATE
0005  kplotaxis.cpp
0006  kplotpoint.cpp
0007  kplotobject.cpp
0008  kplotwidget.cpp
0009 )
0010
0011 generate_export_header(KF5Plotting BASE_NAME KPlotting)
0012
0013 target_include_directories(KF5Plotting INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPlotting>")
0014
0015 target_link_libraries(KF5Plotting PUBLIC Qt${QT_MAJOR_VERSION}::Widgets)
0016
0017 set_target_properties(KF5Plotting PROPERTIES VERSION   ${KPLOTTING_VERSION}
0018                                              SOVERSION ${KPLOTTING_SOVERSION}
0019                                              EXPORT_NAME Plotting
0020 )
0021
0022 ecm_generate_headers(KPlotting_HEADERS
0023   HEADER_NAMES
0024   KPlotAxis
0025   KPlotPoint
0026   KPlotObject
0027   KPlotWidget
0028
0029   REQUIRED_HEADERS KPlotting_HEADERS
0030 )
0031
0032 install(TARGETS KF5Plotting EXPORT KF5PlottingTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0033
0034 install(FILES
0035   ${CMAKE_CURRENT_BINARY_DIR}/kplotting_export.h
0036   ${KPlotting_HEADERS}
0037   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPlotting COMPONENT Devel
0038 )
0039
0040 if (BUILD_DESIGNERPLUGIN)
0041     add_subdirectory(designer)
0042 endif()
0043
0044 if(BUILD_QCH)
0045     ecm_add_qch(
0046         KF5Plotting_QCH
0047         NAME KPlotting
0048         BASE_NAME KF5Plotting
0049         VERSION ${KF_VERSION}
0050         ORG_DOMAIN org.kde
0051         SOURCES # using only public headers, to cover only public API
0052             ${KPlotting_HEADERS}
0053         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0054         LINK_QCHS
0055             Qt5Widgets_QCH
0056         INCLUDE_DIRS
0057             ${CMAKE_CURRENT_BINARY_DIR}
0058         BLANK_MACROS
0059             KPLOTTING_EXPORT
0060             KPLOTTING_DEPRECATED
0061             KPLOTTING_DEPRECATED_EXPORT
0062         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0063         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0064         COMPONENT Devel
0065     )
0066 endif()
0067
0068
0069 include(ECMGeneratePriFile)
0070 ecm_generate_pri_file(BASE_NAME KPlotting LIB_NAME KF5Plotting DEPS "widgets" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KPlotting)
0071 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})