src/widgets/CMakeLists.txt

0001 add_library(KF6PeopleWidgets)
0002 add_library(KF6::PeopleWidgets ALIAS KF6PeopleWidgets)
0003
0004 set_target_properties(KF6PeopleWidgets PROPERTIES
0005     VERSION     ${KPEOPLE_VERSION}
0006     SOVERSION   ${KPEOPLE_SOVERSION}
0007     EXPORT_NAME PeopleWidgets
0008 )
0009
0010 target_sources(KF6PeopleWidgets PRIVATE
0011     persondetailsdialog.cpp
0012     persondetailsview.cpp
0013     persondetailsdialog.cpp
0014     emaildetailswidget.cpp
0015     abstractfieldwidgetfactory.cpp
0016
0017     mergedialog.cpp
0018     mergedelegate.cpp
0019 )
0020
0021 ecm_generate_export_header(KF6PeopleWidgets
0022     EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kpeople/widgets/kpeoplewidgets_export.h
0023     BASE_NAME KPeopleWidgets
0024     GROUP_BASE_NAME KF
0025     VERSION ${KF_VERSION}
0026     USE_VERSION_HEADER
0027     VERSION_BASE_NAME KPeople
0028     DEPRECATED_BASE_VERSION 0
0029 )
0030
0031 ecm_qt_declare_logging_category(KF6PeopleWidgets
0032     HEADER kpeople_widgets_debug.h
0033     IDENTIFIER KPEOPLE_WIDGETS_LOG
0034     CATEGORY_NAME kf.people.widgets
0035     OLD_CATEGORY_NAMES kf5.kpeople.widgets
0036     DESCRIPTION "kpeople widgets"
0037     EXPORT KPEOPLE
0038 )
0039
0040 ki18n_wrap_ui(KF6PeopleWidgets person-details-presentation.ui)
0041
0042 target_link_libraries (KF6PeopleWidgets
0043                     PUBLIC
0044                         KF6::People
0045                         Qt6::Widgets
0046                     PRIVATE
0047                         KF6::I18n
0048                         KF6::ItemViews
0049                         KF6::WidgetsAddons
0050                         KF6::PeopleBackend
0051                         KF6::CoreAddons
0052 )
0053
0054 if (MSVC)
0055     set_target_properties (KF6PeopleWidgets PROPERTIES
0056                            OUTPUT_NAME libKPeopleWidgets
0057     )
0058 endif (MSVC)
0059
0060 # Install:
0061 install (TARGETS KF6PeopleWidgets
0062          EXPORT KPeopleTargets
0063          ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0064 )
0065
0066 ecm_generate_headers(KPeopleWidgets_CamelCase_HEADERS
0067     HEADER_NAMES
0068             AbstractFieldWidgetFactory
0069             PersonDetailsView
0070             MergeDialog
0071             PersonDetailsDialog
0072     REQUIRED_HEADERS KPeopleWidgets_HEADERS
0073     PREFIX KPeople/Widgets
0074 )
0075
0076 install (FILES ${KPeopleWidgets_CamelCase_HEADERS}
0077          DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/KPeople/Widgets
0078          COMPONENT Devel
0079 )
0080 install(FILES
0081   ${CMAKE_CURRENT_BINARY_DIR}/kpeople/widgets/kpeoplewidgets_export.h
0082   ${KPeopleWidgets_HEADERS}
0083   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeople/widgets COMPONENT Devel
0084 )
0085
0086 # make available to ecm_add_qch in parent folder
0087 set(KPeopleWidgets_QCH_SOURCES ${KPeopleWidgets_HEADERS} PARENT_SCOPE)