kparts/src/CMakeLists.txt

0001 add_library(KF6Parts)
0002 add_library(KF6::Parts ALIAS KF6Parts)
0003
0004 set_target_properties(KF6Parts PROPERTIES
0005     VERSION     ${KPARTS_VERSION}
0006     SOVERSION   ${KPARTS_SOVERSION}
0007     EXPORT_NAME Parts
0008 )
0009
0010 target_sources(KF6Parts PRIVATE
0011     partbase.cpp
0012     part.cpp
0013     partloader.cpp
0014     openurlarguments.cpp
0015     readonlypart.cpp
0016     readwritepart.cpp
0017     partmanager.cpp
0018     mainwindow.cpp
0019     guiactivateevent.cpp
0020     partactivateevent.cpp
0021     navigationextension.cpp
0022     openurlevent.cpp
0023     statusbarextension.cpp
0024     fileinfoextension.cpp
0025     listingfilterextension.cpp
0026     listingnotificationextension.cpp
0027 )
0028
0029 include(ECMGenerateHeaders)
0030 ecm_generate_headers(KParts_CamelCase_HEADERS
0031     HEADER_NAMES
0032         FileInfoExtension
0033         GUIActivateEvent
0034         ListingFilterExtension
0035         ListingNotificationExtension
0036         MainWindow
0037         NavigationExtension
0038         OpenUrlArguments
0039         OpenUrlEvent
0040         Part
0041         PartActivateEvent
0042         PartBase
0043         PartLoader
0044         PartManager
0045         ReadOnlyPart
0046         ReadWritePart
0047         StatusBarExtension
0048     REQUIRED_HEADERS KParts_HEADERS
0049     PREFIX KParts
0050 )
0051 install(FILES ${KParts_CamelCase_HEADERS}
0052         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KParts/KParts
0053         COMPONENT Devel)
0054
0055 ecm_qt_declare_logging_category(KF6Parts
0056     HEADER kparts_logging.h
0057     IDENTIFIER KPARTSLOG
0058     CATEGORY_NAME kf.parts
0059     DESCRIPTION "KParts"
0060     EXPORT KPARTSLOG
0061 )
0062
0063 ecm_generate_export_header(KF6Parts
0064     EXPORT_FILE_NAME ${KParts_BINARY_DIR}/kparts/kparts_export.h
0065     BASE_NAME KParts
0066     GROUP_BASE_NAME KF
0067     VERSION ${KF_VERSION}
0068     USE_VERSION_HEADER
0069     DEPRECATED_BASE_VERSION 0
0070     DEPRECATION_VERSIONS
0071     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0072 )
0073
0074 target_include_directories(KF6Parts
0075     PUBLIC "$<BUILD_INTERFACE:${KParts_BINARY_DIR}>"
0076     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KParts>"
0077 )
0078
0079 target_link_libraries(KF6Parts
0080     PUBLIC
0081         KF6::KIOCore # KFileItem used in FileInfoExtension API
0082         KF6::XmlGui # essential to the technology
0083     PRIVATE
0084         KF6::Service
0085         KF6::I18n
0086         KF6::JobWidgets
0087         KF6::KIOWidgets
0088 )
0089
0090 install(TARGETS KF6Parts EXPORT KF6PartsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0091
0092 install(FILES
0093   ${KParts_BINARY_DIR}/kparts/kparts_export.h
0094   ${KParts_HEADERS}
0095   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KParts/kparts COMPONENT Devel
0096 )
0097
0098 install(FILES kde_terminal_interface.h DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KParts )
0099
0100 ecm_qt_install_logging_categories(
0101     EXPORT KPARTSLOG
0102     FILE kparts.categories
0103     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0104 )
0105
0106 if(BUILD_QCH)
0107     ecm_add_qch(
0108         KF6Parts_QCH
0109         NAME KParts
0110         BASE_NAME KF6Parts
0111         VERSION ${KF_VERSION}
0112         ORG_DOMAIN org.kde
0113         SOURCES # using only public headers, to cover only public API
0114             ${KParts_HEADERS}
0115             kde_terminal_interface.h
0116         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0117         LINK_QCHS
0118             KF6KIO_QCH
0119             KF6XmlGui_QCH
0120         INCLUDE_DIRS
0121             ${CMAKE_BINARY_DIR}
0122             ${CMAKE_CURRENT_BINARY_DIR}
0123         BLANK_MACROS
0124             KPARTS_EXPORT
0125             KPARTS_DEPRECATED
0126             KPARTS_DEPRECATED_EXPORT
0127             "KPARTS_DEPRECATED_VERSION(x, y, t)"
0128             "KPARTS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0129             "KPARTS_DEPRECATED_VERSION(x, y, t)"
0130             "KPARTS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0131         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0132         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0133         COMPONENT Devel
0134     )
0135 endif()
0136