frameworks/kparts/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KParts VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019 include(KDEPackageAppTemplates)
0020 include(ECMAddQch)
0021
0022 include(ECMGenerateExportHeader)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMSetupVersion)
0025 include(ECMDeprecationSettings)
0026
0027 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control how much of deprecated API is build [default=0].")
0028
0029 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0030 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0031
0032 ecm_setup_version(PROJECT VARIABLE_PREFIX KPARTS
0033                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kparts_version.h"
0034                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5PartsConfigVersion.cmake"
0035                         SOVERSION 5)
0036
0037 set(REQUIRED_QT_VERSION 5.15.2)
0038 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Widgets Xml)
0039
0040 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0041 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0042 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0043 find_package(KF5IconThemes ${KF_DEP_VERSION} REQUIRED)
0044 find_package(KF5KIO ${KF_DEP_VERSION} REQUIRED)
0045 find_package(KF5JobWidgets ${KF_DEP_VERSION} REQUIRED)
0046 find_package(KF5Service ${KF_DEP_VERSION} REQUIRED)
0047 find_package(KF5TextWidgets ${KF_DEP_VERSION} REQUIRED)
0048 find_package(KF5WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0049 find_package(KF5XmlGui ${KF_DEP_VERSION} REQUIRED)
0050
0051 ecm_set_disabled_deprecation_versions(
0052   QT 5.15.2
0053   KF 5.97
0054   KIOWIDGETS 5.70 # We need KRun for BrowserRun
0055   KCOREADDONS 5.64 # We need KAboutData::fromPluginMetaData
0056   KSERVICE 5.81 # We need KMimeTypeTrader and KPluginInfo(KService)
0057 )
0058
0059 if(BUILD_TESTING)
0060   add_subdirectory( tests )
0061   add_subdirectory( autotests )
0062 endif()
0063 add_definitions(-DTRANSLATION_DOMAIN=\"kparts5\")
0064 ki18n_install(po)
0065
0066 add_subdirectory( src )
0067 add_subdirectory(templates)
0068
0069 # create a Config.cmake and a ConfigVersion.cmake file and install them
0070 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Parts")
0071
0072 if (BUILD_QCH)
0073     ecm_install_qch_export(
0074         TARGETS KF5Parts_QCH
0075         FILE KF5PartsQchTargets.cmake
0076         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0077         COMPONENT Devel
0078     )
0079     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5PartsQchTargets.cmake\")")
0080 endif()
0081
0082 include(CMakePackageConfigHelpers)
0083
0084 configure_package_config_file(
0085   "${CMAKE_CURRENT_SOURCE_DIR}/KF5PartsConfig.cmake.in"
0086   "${CMAKE_CURRENT_BINARY_DIR}/KF5PartsConfig.cmake"
0087   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0088 )
0089
0090 install(FILES
0091   "${CMAKE_CURRENT_BINARY_DIR}/KF5PartsConfig.cmake"
0092   "${CMAKE_CURRENT_BINARY_DIR}/KF5PartsConfigVersion.cmake"
0093   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0094   COMPONENT Devel
0095 )
0096
0097 install(EXPORT KF5PartsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5PartsTargets.cmake NAMESPACE KF5:: )
0098
0099 install(FILES
0100   ${CMAKE_CURRENT_BINARY_DIR}/kparts_version.h
0101   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KParts COMPONENT Devel
0102 )
0103
0104 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0105
0106 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)