kmediaplayer/src/CMakeLists.txt

0001 add_library(KF5MediaPlayer)
0002 add_library(KF5::MediaPlayer ALIAS KF5MediaPlayer)
0003
0004 target_sources(KF5MediaPlayer PRIVATE
0005    player.cpp
0006    view.cpp
0007    kmediaplayeradaptor.cpp
0008 )
0009
0010 generate_export_header(KF5MediaPlayer BASE_NAME KMediaPlayer)
0011
0012 # Apps must include <KMediaPlayer/File> or <kmediaplayer/file.h>
0013 target_include_directories(KF5MediaPlayer INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KMediaPlayer>")
0014
0015 target_link_libraries(KF5MediaPlayer PUBLIC
0016    Qt5::Widgets
0017    KF5::Parts
0018 )
0019 target_link_libraries(KF5MediaPlayer PRIVATE
0020    KF5::XmlGui
0021 )
0022 set_target_properties(KF5MediaPlayer PROPERTIES
0023    VERSION ${KMEDIAPLAYER_VERSION}
0024    SOVERSION ${KMEDIAPLAYER_SOVERSION}
0025    EXPORT_NAME MediaPlayer
0026 )
0027
0028 ecm_generate_headers(KMediaPlayer_CamelCase_HEADERS
0029   HEADER_NAMES
0030   Player
0031   View
0032
0033   PREFIX KMediaPlayer
0034   REQUIRED_HEADERS KMediaPlayer_HEADERS
0035 )
0036 install(FILES ${KMediaPlayer_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KMediaPlayer/KMediaPlayer COMPONENT Devel)
0037
0038 install(TARGETS KF5MediaPlayer
0039         EXPORT KF5MediaPlayerTargets
0040         ${KF5_INSTALL_TARGETS_DEFAULT_ARGS}
0041 )
0042 install(FILES
0043   ${CMAKE_CURRENT_BINARY_DIR}/kmediaplayer_export.h
0044   ${KMediaPlayer_HEADERS}
0045   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KMediaPlayer/kmediaplayer
0046   COMPONENT Devel
0047 )
0048
0049 install(FILES
0050    kmediaplayer-engine.desktop
0051    kmediaplayer-player.desktop
0052    DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
0053 install(FILES
0054    org.kde.KMediaPlayer.xml
0055    DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0056    RENAME kf5_org.kde.KMediaPlayer.xml)