src/kjsembed/CMakeLists.txt

0001 add_library(KF5JsEmbed)
0002 add_library(KF5::JsEmbed ALIAS KF5JsEmbed)
0003
0004 target_sources(KF5JsEmbed PRIVATE
0005    kjseglobal.cpp
0006    binding_support.cpp
0007    static_binding.cpp
0008    variant_binding.cpp
0009    object_binding.cpp
0010    builtins.cpp
0011    fileio.cpp
0012    jseventmapper.cpp
0013    eventproxy.cpp
0014    slotproxy.cpp
0015    jseventutils.cpp
0016    qobject_binding.cpp
0017    kjsembed.cpp
0018    value_binding.cpp
0019    iosupport.cpp
0020    qwidget_binding.cpp
0021    qaction_binding.cpp
0022    qlayout_binding.cpp
0023    qpainter_binding.cpp
0024    settings.cpp
0025    svg_binding.cpp
0026    filedialog_binding.cpp
0027    application.cpp
0028    color.cpp dom.cpp font.cpp image.cpp pen.cpp
0029    pixmap.cpp point.cpp rect.cpp size.cpp url.cpp
0030    brush.cpp
0031    QBrush_bind.cpp
0032    quiloader_binding.cpp
0033 )
0034
0035 generate_export_header(KF5JsEmbed BASE_NAME KJsEmbed)
0036 target_include_directories(KF5JsEmbed PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/..;${CMAKE_CURRENT_BINARY_DIR}/..>")
0037 target_include_directories(KF5JsEmbed INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KJsEmbed>"
0038                                                 "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KJsEmbed/kjsembed>")
0039 ecm_generate_headers(KJsEmbed_CamelCase_HEADERS
0040   HEADER_NAMES
0041     KJsEmbed
0042
0043     PREFIX KJsEmbed
0044     REQUIRED_HEADERS KJsEmbed_HEADERS
0045 )
0046
0047 target_link_libraries(KF5JsEmbed
0048     PUBLIC  KF5::I18n KF5::JS
0049     PRIVATE
0050         #all these are required for its respective bindings
0051         Qt5::Widgets
0052         Qt5::UiTools
0053         Qt5::Xml
0054         Qt5::Svg
0055 )
0056
0057 set_target_properties(KF5JsEmbed PROPERTIES VERSION   "${KJSEMBED_VERSION}"
0058                                             SOVERSION "${KJSEMBED_SOVERSION}"
0059                                             EXPORT_NAME JsEmbed
0060 )
0061
0062 install(TARGETS KF5JsEmbed EXPORT KF5JsEmbedTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
0063
0064 install(FILES
0065  ${CMAKE_CURRENT_BINARY_DIR}/kjsembed_export.h
0066  ${KJsEmbed_HEADERS}
0067
0068  pointer.h
0069  kjseglobal.h
0070  static_binding.h
0071  binding_support.h
0072  variant_binding.h
0073
0074  DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KJsEmbed/kjsembed COMPONENT Devel)
0075
0076 install(FILES ${KJsEmbed_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KJsEmbed/KJsEmbed COMPONENT Devel)
0077
0078
0079
0080
0081 include(ECMGeneratePriFile)
0082 ecm_generate_pri_file(BASE_NAME KJsEmbed LIB_NAME KF5JsEmbed DEPS "KI18n KJS" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KJsEmbed)
0083 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})