kjs/autotests/CMakeLists.txt

0001 include(ECMAddTests)
0002
0003 find_package(Qt5Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0004 ########### ecmatest ##############
0005
0006 add_executable(ecmatest
0007   ecmatest.cpp
0008 )
0009 ecm_mark_nongui_executable(ecmatest)
0010 ecm_mark_as_test(ecmatest)
0011 target_link_libraries(ecmatest KF5::JS Qt5::Test)
0012
0013 function(ADD_ECMATEST ECMA262_CHAPTER)
0014    if (IS_DIRECTORY "${ECMATEST_BASEDIR}/test/suite/${ECMA262_CHAPTER}")
0015       string(REPLACE "/15" "" ECMA262_TESTNAME "${ECMA262_CHAPTER}")
0016       add_test(NAME ECMAscript262_${ECMA262_TESTNAME} COMMAND ecmatest)
0017       if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/ecmatest_broken_${ECMA262_TESTNAME}")
0018          set(_test262_broken_env ";ECMATEST_BROKEN=${CMAKE_CURRENT_SOURCE_DIR}/ecmatest_broken_${ECMA262_TESTNAME}")
0019       else ()
0020          set(_test262_broken_env)
0021       endif ()
0022       set_tests_properties(ECMAscript262_${ECMA262_TESTNAME} PROPERTIES ENVIRONMENT "ECMATEST_BASEDIR=${ECMATEST_BASEDIR};ECMATEST_CHAPTER=${ECMA262_CHAPTER}${_test262_broken_env}")
0023    endif ()
0024 endfunction(ADD_ECMATEST)
0025
0026 if (BUILD_TESTING)
0027    set(ECMATEST_BASEDIR "" CACHE PATH "path to checkout of ECMAscript Tests262 checkout")
0028    if (ECMATEST_BASEDIR)
0029       file(GLOB _test262_chapters RELATIVE "${ECMATEST_BASEDIR}/test/suite/" "${ECMATEST_BASEDIR}/test/suite/*")
0030       list(SORT _test262_chapters)
0031       # The "Intl" object is not implemented (see bug 299962)
0032       list(REMOVE_ITEM _test262_chapters "intl402")
0033       # ch15 is way too big, split it into several subchapters
0034       list(REMOVE_ITEM _test262_chapters "ch15")
0035       foreach (_test262_chapter ${_test262_chapters})
0036          ADD_ECMATEST(${_test262_chapter})
0037       endforeach ()
0038
0039       # now ch15
0040       file(GLOB _test262_15_chapters RELATIVE "${ECMATEST_BASEDIR}/test/suite/ch15" "${ECMATEST_BASEDIR}/test/suite/ch15/*")
0041       list(SORT _test262_15_chapters)
0042       foreach (_test262_15_chapter ${_test262_15_chapters})
0043          ADD_ECMATEST(ch15/${_test262_15_chapter})
0044       endforeach ()
0045    endif ()
0046 endif ()
0047
0048 ##################### kjsapitest ################
0049
0050 ecm_add_test(kjsapitest.cpp LINK_LIBRARIES KF5::JSApi Qt5::Test)