frameworks/kjobwidgets/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KJobWidgets VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMPoQmTools)
0021 include(ECMGenerateExportHeader)
0022 include(ECMSetupVersion)
0023 include(ECMGenerateHeaders)
0024 include(ECMDeprecationSettings)
0025 include(ECMAddQch)
0026 include(CMakePackageConfigHelpers)
0027
0028 set(REQUIRED_QT_VERSION 6.5.0)
0029 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0030
0031 if (NOT ANDROID)
0032     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0033 endif()
0034 if (NOT APPLE)
0035     find_package(X11)
0036 endif()
0037
0038 set(HAVE_X11 ${X11_FOUND})
0039
0040 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0041 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0042 find_package(KF6Notifications ${KF_DEP_VERSION} REQUIRED)
0043
0044 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0045
0046 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0047 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0048
0049 set(kjobwidgets_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kjobwidgets_version.h")
0050 ecm_setup_version(PROJECT VARIABLE_PREFIX KJOBWIDGETS
0051                         VERSION_HEADER "${kjobwidgets_version_header}"
0052                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6JobWidgetsConfigVersion.cmake"
0053                         SOVERSION 6)
0054
0055 ecm_set_disabled_deprecation_versions(
0056     QT 6.5
0057     KF 5.240
0058 )
0059
0060 ecm_install_po_files_as_qm(poqm)
0061
0062 add_subdirectory(src)
0063 if (BUILD_TESTING)
0064     add_subdirectory(tests)
0065     add_subdirectory(autotests)
0066 endif()
0067
0068 # create a Config.cmake and a ConfigVersion.cmake file and install them
0069 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6JobWidgets")
0070
0071 if (BUILD_QCH)
0072     ecm_install_qch_export(
0073         TARGETS KF6JobWidgets_QCH
0074         FILE KF6JobWidgetsQchTargets.cmake
0075         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0076         COMPONENT Devel
0077     )
0078     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6JobWidgetsQchTargets.cmake\")")
0079 endif()
0080
0081 configure_package_config_file(
0082   "${CMAKE_CURRENT_SOURCE_DIR}/KF6JobWidgetsConfig.cmake.in"
0083   "${CMAKE_CURRENT_BINARY_DIR}/KF6JobWidgetsConfig.cmake"
0084   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0085   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0086 )
0087
0088 install(FILES
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF6JobWidgetsConfig.cmake"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF6JobWidgetsConfigVersion.cmake"
0091   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092   COMPONENT Devel
0093 )
0094
0095 install(EXPORT KF6JobWidgetsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6JobWidgetsTargets.cmake NAMESPACE KF6:: )
0096
0097 install(FILES
0098    ${kjobwidgets_version_header}
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets COMPONENT Devel
0100 )
0101
0102 include(ECMFeatureSummary)
0103 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0104
0105 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)