frameworks/kitemviews/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.240.0") # handled by release scripts
0004 project(KItemViews VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.240.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016
0017 include(KDEGitCommitHooks)
0018 include(ECMGenerateExportHeader)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMQtDeclareLoggingCategory)
0022 include(ECMDeprecationSettings)
0023 include(ECMAddQch)
0024 include(ECMPoQmTools)
0025 include(CMakeDependentOption)
0026 include(CMakePackageConfigHelpers)
0027
0028 set(REQUIRED_QT_VERSION 6.5.0)
0029 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0030
0031 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0037 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0038
0039 set(kitemviews_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kitemviews_version.h")
0040 ecm_setup_version(PROJECT VARIABLE_PREFIX KITEMVIEWS
0041                         VERSION_HEADER "${kitemviews_version_header}"
0042                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfigVersion.cmake"
0043                         SOVERSION 6)
0044
0045
0046 ecm_install_po_files_as_qm(poqm)
0047
0048 ecm_set_disabled_deprecation_versions(
0049     QT 6.4
0050 )
0051
0052 add_subdirectory(src)
0053 if (BUILD_TESTING)
0054     add_subdirectory(autotests)
0055     add_subdirectory(tests)
0056 endif()
0057
0058 # create a Config.cmake and a ConfigVersion.cmake file and install them
0059 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ItemViews")
0060
0061 if (BUILD_QCH)
0062     ecm_install_qch_export(
0063         TARGETS KF6ItemViews_QCH
0064         FILE KF6ItemViewsQCHTargets.cmake
0065         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0066     )
0067     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ItemViewsQCHTargets.cmake\")")
0068 endif()
0069
0070 configure_package_config_file(
0071   "${CMAKE_CURRENT_SOURCE_DIR}/KF6ItemViewsConfig.cmake.in"
0072   "${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfig.cmake"
0073   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0074 )
0075
0076 install(FILES
0077   "${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfig.cmake"
0078   "${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfigVersion.cmake"
0079   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0080   COMPONENT Devel
0081 )
0082
0083 install(EXPORT KF6ItemViewsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ItemViewsTargets.cmake NAMESPACE KF6:: )
0084
0085 install(FILES
0086    ${kitemviews_version_header}
0087   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews COMPONENT Devel
0088 )
0089
0090 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0091
0092 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)