frameworks/kitemmodels/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 project(KItemModels VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.106.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022 include(ECMGenerateExportHeader)
0023 include(ECMDeprecationSettings)
0024 include(ECMAddQch)
0025 include(CMakePackageConfigHelpers)
0026 include(ECMQmlModule)
0027
0028 set(REQUIRED_QT_VERSION 5.15.2)
0029 find_package(Qt${QT_MAJOR_VERSION}Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0030 find_package(Qt${QT_MAJOR_VERSION}Qml ${REQUIRED_QT_VERSION} NO_MODULE)
0031
0032 set_package_properties(Qt${QT_MAJOR_VERSION}Qml PROPERTIES
0033         TYPE OPTIONAL
0034         PURPOSE "Build QML import for KItemModels"
0035 )
0036
0037
0038 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0039
0040 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0041 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0042
0043 ecm_setup_version(PROJECT VARIABLE_PREFIX KITEMMODELS
0044                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kitemmodels_version.h"
0045                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ItemModelsConfigVersion.cmake"
0046                         SOVERSION 5)
0047
0048 ecm_set_disabled_deprecation_versions(
0049     QT 5.15.2
0050 )
0051
0052 add_subdirectory(src)
0053 if (BUILD_TESTING)
0054     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Test Widgets)
0055     find_package(Qt${QT_MAJOR_VERSION}QuickWidgets ${REQUIRED_QT_VERSION} NO_MODULE)
0056     set_package_properties(Qt${QT_MAJOR_VERSION}QuickWidgets PROPERTIES
0057         TYPE OPTIONAL
0058         PURPOSE "Build proxymodeltestapp QML selection and QML treeview examples"
0059     )
0060     set_package_properties(Qt${QT_MAJOR_VERSION}Script PROPERTIES
0061         TYPE OPTIONAL
0062         PURPOSE "Build proxymodeltestapp reparenting example"
0063     )
0064     find_package(Qt${QT_MAJOR_VERSION}Script ${REQUIRED_QT_VERSION} NO_MODULE)
0065     add_subdirectory(autotests)
0066     add_subdirectory(tests)
0067 endif()
0068
0069
0070 # create a Config.cmake and a ConfigVersion.cmake file and install them
0071 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5ItemModels")
0072
0073 if (BUILD_QCH)
0074     ecm_install_qch_export(
0075         TARGETS KF5ItemModels_QCH
0076         FILE KF5ItemModelsQCHTargets.cmake
0077         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0078     )
0079     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ItemModelsQCHTargets.cmake\")")
0080 endif()
0081
0082 configure_package_config_file(
0083   "${CMAKE_CURRENT_SOURCE_DIR}/KF5ItemModelsConfig.cmake.in"
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF5ItemModelsConfig.cmake"
0085   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0086 )
0087
0088 install(FILES
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF5ItemModelsConfig.cmake"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF5ItemModelsConfigVersion.cmake"
0091   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092   COMPONENT Devel
0093 )
0094
0095 install(EXPORT KF5ItemModelsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5ItemModelsTargets.cmake NAMESPACE KF5:: )
0096
0097 install(FILES
0098    ${CMAKE_CURRENT_BINARY_DIR}/kitemmodels_version.h
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels COMPONENT Devel
0100 )
0101
0102 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0103
0104 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)