examples/wheelhandler/ScrollViewUsage.qml

0001 /* SPDX-FileCopyrightText: 2021 Noah Davis <noahadvs@gmail.com>
0002  * SPDX-License-Identifier: LGPL-2.1-only OR LGPL-3.0-only OR LicenseRef-KDE-Accepted-LGPL
0003  */
0004
0005 import QtQuick
0006 import QtQuick.Templates as T
0007 import QtQuick.Controls as QQC2
0008 import org.kde.kirigami as Kirigami
0009
0010 T.ScrollView {
0011     id: control
0012
0013     implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
0014                             contentWidth + leftPadding + rightPadding)
0015     implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
0016                              contentHeight + topPadding + bottomPadding)
0017
0018     leftPadding: mirrored && T.ScrollBar.vertical.visible && !Kirigami.Settings.isMobile ? T.ScrollBar.vertical.width : 0
0019     rightPadding: !mirrored && T.ScrollBar.vertical.visible && !Kirigami.Settings.isMobile ? T.ScrollBar.vertical.width : 0
0020     bottomPadding: T.ScrollBar.horizontal.visible && !Kirigami.Settings.isMobile ? T.ScrollBar.horizontal.height : 0
0021
0022     data: [
0023         Kirigami.WheelHandler {
0024             id: wheelHandler
0025             target: control.contentItem
0026         }
0027     ]
0028
0029     T.ScrollBar.vertical: QQC2.ScrollBar {
0030         parent: control
0031         x: control.mirrored ? 0 : control.width - width
0032         y: control.topPadding
0033         height: control.availableHeight
0034         active: control.T.ScrollBar.horizontal.active
0035         stepSize: wheelHandler.verticalStepSize / control.contentHeight
0036     }
0037
0038     T.ScrollBar.horizontal: QQC2.ScrollBar {
0039         parent: control
0040         x: control.leftPadding
0041         y: control.height - height
0042         width: control.availableWidth
0043         active: control.T.ScrollBar.vertical.active
0044         stepSize: wheelHandler.horizontalStepSize / control.contentWidth
0045     }
0046 }