kirigami/autotests/CMakeLists.txt

0001 if(NOT TARGET Qt6::QuickTest)
0002     message(STATUS "Qt6QuickTest not found, autotests will not be built.")
0003     return()
0004 endif()
0005
0006 add_executable(qmltest qmltest.cpp)
0007 target_link_libraries(qmltest PRIVATE Qt6::Qml Qt6::QuickTest)
0008
0009 if (BUILD_SHARED_LIBS)
0010     target_link_libraries(qmltest PRIVATE Kirigami)
0011 else()
0012     target_link_libraries(qmltest PRIVATE Kirigamiplugin)
0013 endif()
0014
0015 macro(kirigami_add_tests)
0016     if (WIN32)
0017         set(_extra_args -platform offscreen)
0018     endif()
0019
0020     if (BUILD_SHARED_LIBS)
0021         set(_extra_args ${_extra_args} -import ${CMAKE_BINARY_DIR}/bin)
0022     endif()
0023
0024     foreach(test ${ARGV})
0025         add_test(NAME ${test}
0026                  COMMAND qmltest
0027                         ${_extra_args}
0028                         -input ${test}
0029                  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
0030         )
0031     endforeach()
0032 endmacro()
0033
0034 kirigami_add_tests(
0035     tst_actiontoolbar.qml
0036     tst_colorutils.qml
0037     tst_columnview.qml
0038     tst_delegates.qml
0039     tst_dialogs.qml
0040     tst_formlayout.qml
0041     tst_globaldrawer.qml
0042     tst_headerfooterlayout.qml
0043     tst_icon.qml
0044     tst_ImageColors.qml
0045     tst_inlinemessage.qml
0046     tst_inlineviewheader.qml
0047     tst_keynavigation.qml
0048     tst_listskeynavigation.qml
0049     tst_menudialog.qml
0050     tst_mnemonicdata.qml
0051     tst_navigationtabbar.qml
0052     tst_overlaysheet.qml
0053     tst_overlayzstacking.qml
0054     tst_padding.qml
0055     tst_pagerow.qml
0056     tst_placeholdermessage.qml
0057     tst_sceneposition.qml
0058     tst_scrollablepage.qml
0059     tst_spellcheck.qml
0060     tst_theme.qml
0061
0062     mobile/tst_pagerow.qml
0063
0064     pagepool/tst_layers.qml
0065     pagepool/tst_pagepool.qml
0066
0067     wheelhandler/tst_filterMouseEvents.qml
0068     wheelhandler/tst_invokables.qml
0069     wheelhandler/tst_onWheel.qml
0070     wheelhandler/tst_scrolling.qml
0071 )
0072
0073 set_tests_properties(
0074     tst_actiontoolbar.qml
0075     tst_theme.qml
0076
0077     PROPERTIES
0078         ENVIRONMENT "QT_QUICK_CONTROLS_STYLE=Basic;KIRIGAMI_FORCE_STYLE=1"
0079 )
0080
0081 set_tests_properties(
0082     mobile/tst_pagerow.qml
0083
0084     PROPERTIES
0085         ENVIRONMENT "QT_QUICK_CONTROLS_MOBILE=1"
0086 )