Warning, /frameworks/kio/src/widgets/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 #include (ConfigureChecks.cmake)
0002 
0003 set_package_properties(ACL PROPERTIES DESCRIPTION "LibACL" URL "ftp://oss.sgi.com/projects/xfs/cmd_tars"
0004                        TYPE RECOMMENDED PURPOSE "Support for manipulating access control lists")
0005 configure_file(config-kiowidgets.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kiowidgets.h)
0006 
0007 add_library(KF6KIOWidgets)
0008 add_library(KF6::KIOWidgets ALIAS KF6KIOWidgets)
0009 
0010 set_target_properties(KF6KIOWidgets PROPERTIES
0011     VERSION     ${KIO_VERSION}
0012     SOVERSION   ${KIO_SOVERSION}
0013     EXPORT_NAME KIOWidgets
0014 )
0015 
0016 set(kiowidgets_dbus_SRCS)
0017 if(TARGET Qt6::DBus)
0018     qt_add_dbus_adaptor(kiowidgets_dbus_SRCS org.kde.kio.FileUndoManager.xml fileundomanager_p.h KIO::FileUndoManagerPrivate fileundomanager_adaptor KIOFileUndoManagerAdaptor)
0019     qt_add_dbus_interface(kiowidgets_dbus_SRCS org.kde.kuiserver.xml kuiserver_interface)
0020 endif()
0021 
0022 
0023 target_sources(KF6KIOWidgets PRIVATE
0024   kacleditwidget.cpp
0025   kurlrequesterdialog.cpp
0026   kurlcombobox.cpp
0027   kfileitemactions.cpp
0028   imagefilter.cpp
0029   kopenwithdialog.cpp
0030   kfile.cpp
0031   pastedialog.cpp
0032   clipboardupdater.cpp
0033   kabstractfileitemactionplugin.cpp
0034   kurlrequester.cpp
0035   kshellcompletion.cpp
0036   kurlcompletion.cpp
0037   renamedialog.cpp
0038   ksslcertificatebox.cpp
0039   ksslinfodialog.cpp
0040   skipdialog.cpp
0041   jobuidelegate.cpp
0042   kdirlister.cpp
0043   executablefileopendialog.cpp
0044   kurifiltersearchprovideractions.cpp
0045   widgetsuntrustedprogramhandler.cpp
0046   widgetsopenwithhandler.cpp
0047   widgetsopenorexecutefilehandler.cpp
0048   widgetsaskuseractionhandler.cpp
0049 )
0050 
0051 if(NOT ANDROID)
0052 target_sources(KF6KIOWidgets PRIVATE
0053   ${kiowidgets_dbus_SRCS}
0054   deleteortrashjob.cpp
0055   fileundomanager.cpp
0056   kpropertiesdialog.cpp
0057   kpropertiesdialogplugin.cpp
0058   kpropertiesdialogbuiltin_p.cpp
0059   delegateanimationhandler.cpp
0060   kfileitemdelegate.cpp
0061   paste.cpp
0062   kbuildsycocaprogressdialog.cpp
0063   sslui.cpp
0064   dropjob.cpp
0065   pastejob.cpp
0066   joburlcache.cpp
0067   kdirmodel.cpp
0068   renamefiledialog.cpp
0069 )
0070 endif()
0071 if (NOT ANDROID)
0072     target_sources(KF6KIOWidgets PRIVATE
0073         kdynamicjobtracker.cpp
0074     )
0075 endif()
0076 
0077 ecm_qt_declare_logging_category(KF6KIOWidgets
0078     HEADER kio_widgets_debug.h
0079     IDENTIFIER KIO_WIDGETS
0080     CATEGORY_NAME kf.kio.widgets
0081     OLD_CATEGORY_NAMES kf5.kio.widgets
0082     DESCRIPTION "KIOWidgets (KIO)"
0083     EXPORT KIO
0084 )
0085 
0086 ecm_qt_export_logging_category(
0087     IDENTIFIER category
0088     CATEGORY_NAME kf.kio.widgets.kdirmodel
0089     OLD_CATEGORY_NAMES kf5.kio.kdirmodel
0090     DESCRIPTION "KDirModel (KIO)"
0091     EXPORT KIO
0092 )
0093 
0094 ki18n_wrap_ui(KF6KIOWidgets
0095   checksumswidget.ui
0096   certificateparty.ui
0097   sslinfo.ui
0098   kpropertiesdesktopadvbase.ui
0099   kpropertiesdesktopbase.ui
0100   kfilepropspluginwidget.ui
0101 )
0102 
0103 ecm_generate_export_header(KF6KIOWidgets
0104     BASE_NAME KIOWidgets
0105     GROUP_BASE_NAME KF
0106     VERSION ${KF_VERSION}
0107     USE_VERSION_HEADER
0108     VERSION_BASE_NAME KIO
0109     DEPRECATED_BASE_VERSION 0
0110     DEPRECATION_VERSIONS 5.0
0111     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0112 )
0113 
0114 target_include_directories(KF6KIOWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIOWidgets>")
0115 
0116 target_link_libraries(KF6KIOWidgets
0117   PUBLIC
0118     KF6::KIOGui
0119     KF6::KIOCore
0120     KF6::JobWidgets
0121     KF6::Service
0122     KF6::Solid
0123     Qt6::Network  # SSL
0124     KF6::Completion    # KUrlCompletion uses KCompletion
0125     KF6::WidgetsAddons # keditlistwidget
0126   PRIVATE
0127     Qt6::Concurrent
0128     KF6::I18n
0129     KF6::ConfigGui
0130     KF6::GuiAddons # KIconUtils
0131     KF6::IconThemes   # KIconLoader
0132     KF6::IconWidgets  # KIconButton
0133     KF6::WindowSystem # KStartupInfo
0134     KF6::ColorScheme
0135 )
0136 if (TARGET Qt6::DBus)
0137     target_link_libraries(KF6KIOWidgets
0138         PRIVATE
0139             Qt6::DBus
0140     )
0141 endif()
0142 
0143 if(ACL_FOUND)
0144     target_link_libraries(KF6KIOWidgets PRIVATE ${ACL_LIBS})
0145 endif()
0146 
0147 # Headers not prefixed with KIO/
0148 ecm_generate_headers(KIOWidgets_HEADERS
0149   HEADER_NAMES
0150   KPropertiesDialog
0151   KPropertiesDialogPlugin
0152   KUrlRequesterDialog
0153   KUrlComboBox
0154   KFileItemActions
0155   KFileItemDelegate
0156   KOpenWithDialog
0157   KAbstractFileItemActionPlugin
0158   KBuildSycocaProgressDialog
0159   KFile
0160   KUrlRequester
0161   KSslCertificateBox
0162   KSslInfoDialog
0163   KDirLister
0164   KDirModel
0165   KShellCompletion
0166   KUrlCompletion
0167 
0168   REQUIRED_HEADERS KIOWidgets_HEADERS
0169 )
0170 
0171 # Headers prefixed with KIO/
0172 ecm_generate_headers(KIOWidgets_CamelCase_HEADERS
0173   HEADER_NAMES
0174   DeleteOrTrashJob
0175   SslUi
0176   DropJob
0177   PasteJob
0178   RenameDialog
0179   SkipDialog
0180   JobUiDelegate
0181   FileUndoManager
0182   Paste
0183   KUriFilterSearchProviderActions # KF6: fix and move to non-KIO prefixed install folder
0184   RenameFileDialog
0185   WidgetsAskUserActionHandler
0186 
0187   PREFIX KIO
0188   REQUIRED_HEADERS KIO_namespaced_widgets_HEADERS
0189 )
0190 install(FILES ${KIOWidgets_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOWidgets/KIO COMPONENT Devel)
0191 
0192 install(TARGETS KF6KIOWidgets EXPORT KF6KIOTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0193 
0194 install(FILES
0195   ${KIO_namespaced_widgets_HEADERS}
0196   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOWidgets/kio COMPONENT Devel)
0197 
0198 install(FILES
0199   ${KIOWidgets_HEADERS}
0200   ${CMAKE_CURRENT_BINARY_DIR}/kiowidgets_export.h
0201   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOWidgets COMPONENT Devel)
0202 
0203 # make available to ecm_add_qch in parent folder
0204 set(KIOWidgets_QCH_SOURCES ${KIOWidgets_HEADERS} ${KIO_namespaced_widgets_HEADERS} PARENT_SCOPE)
0205