kioworkers/help/CMakeLists.txt

0001 # kio_help only buildable if doc tools around
0002 if (KF5DocTools_FOUND)
0003
0004 find_package(KF5Archive ${KF_DEP_VERSION} REQUIRED)
0005 find_package(LibXslt)
0006 set_package_properties(LibXslt PROPERTIES
0007                        URL "http://xmlsoft.org/XSLT"
0008                        TYPE REQUIRED
0009                        PURPOSE "Required by the KDE help system to process DocBook XML"
0010                       )
0011
0012 find_package(LibXml2)
0013 set_package_properties(LibXml2 PROPERTIES
0014                        URL "http://xmlsoft.org"
0015                        TYPE REQUIRED
0016                        PURPOSE "Required by the KDE help system to process DocBook XML"
0017                       )
0018
0019 if(NOT LIBXML2_XMLLINT_EXECUTABLE)
0020   message(FATAL_ERROR "xmllint is required by the KDE help system to process DocBook XML")
0021 endif()
0022
0023 include_directories(${LIBXML2_INCLUDE_DIR} ${LIBXSLT_INCLUDE_DIR})
0024
0025 include(ConfigureChecks.cmake)
0026 configure_file(config-help.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-help.h )
0027
0028 #macro_additional_clean_files( ${CMAKE_CURRENT_BINARY_DIR}/checkXML )
0029
0030 find_package(Qt${QT_MAJOR_VERSION}Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0031
0032 ########### next target ###############
0033 kcoreaddons_add_plugin(kio_help INSTALL_NAMESPACE "kf${QT_MAJOR_VERSION}/kio")
0034
0035 target_sources(kio_help PRIVATE
0036     kio_help.cpp
0037     main.cpp
0038     xslt_help.cpp
0039 )
0040
0041 target_link_libraries(kio_help
0042    Qt${QT_MAJOR_VERSION}::Gui # QTextDocument
0043    Qt${QT_MAJOR_VERSION}::Network
0044    KF5::I18n
0045    KF5::Archive
0046    KF5::KIOCore
0047    KF5::DocTools
0048    ${LIBXML2_LIBRARIES}
0049    ${LIBXSLT_LIBRARIES}
0050    ${LIBXSLT_EXSLT_LIBRARIES}
0051 )
0052
0053 install(TARGETS kio_help  DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/kio)
0054
0055
0056 ########### next target ###############
0057 kcoreaddons_add_plugin(kio_ghelp INSTALL_NAMESPACE "kf${QT_MAJOR_VERSION}/kio")
0058
0059 target_sources(kio_ghelp PRIVATE
0060     kio_help.cpp
0061     main_ghelp.cpp
0062     xslt_help.cpp
0063 )
0064
0065 target_link_libraries(kio_ghelp
0066    Qt${QT_MAJOR_VERSION}::Gui # QTextDocument
0067    KF5::I18n
0068    KF5::Archive
0069    KF5::KIOCore
0070    KF5::DocTools
0071    Qt${QT_MAJOR_VERSION}::Network
0072    ${LIBXML2_LIBRARIES}
0073    ${LIBXSLT_LIBRARIES}
0074    ${LIBXSLT_EXSLT_LIBRARIES}
0075 )
0076 if(WIN32)
0077     # libxml/libxslt pulls in windows.h, this breaks QDateTime
0078     target_compile_definitions(kio_help PRIVATE NOMINMAX)
0079     target_compile_definitions(kio_ghelp PRIVATE NOMINMAX)
0080 endif()
0081
0082 endif()