src/kioexec/CMakeLists.txt

0001 kcoreaddons_add_plugin(kioexecd
0002     INSTALL_NAMESPACE "kf${QT_MAJOR_VERSION}/kiod")
0003
0004 set(kioexecd_dbus_SRCS)
0005 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/kioexecd.h org.kde.KIOExecd.xml)
0006 qt_add_dbus_adaptor(kioexecd_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.KIOExecd.xml kioexecd.h KIOExecd)
0007
0008 target_sources(kioexecd PRIVATE
0009     kioexecd.cpp
0010     ${kioexecd_dbus_SRCS}
0011 )
0012
0013 ecm_qt_declare_logging_category(kioexecd
0014     HEADER kioexecdebug.h
0015     IDENTIFIER KIOEXEC
0016     CATEGORY_NAME kf.kio.execd
0017     OLD_CATEGORY_NAMES kf5.kio.execd
0018     DESCRIPTION "kioexecd (KIO)"
0019     EXPORT KIO
0020 )
0021
0022 target_link_libraries(kioexecd KF5::I18n KF5::DBusAddons KF5::WidgetsAddons KF5::KIOCore)
0023
0024 kdbusaddons_generate_dbus_service_file(kiod5 org.kde.kioexecd ${KDE_INSTALL_FULL_LIBEXECDIR_KF})
0025
0026 # next target
0027
0028 add_executable(kioexec)
0029 ecm_mark_nongui_executable(kioexec)
0030
0031 set(kioexec_dbus_SRCS)
0032 qt_add_dbus_interface(kioexec_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.KIOExecd.xml kioexecdinterface)
0033
0034 target_sources(kioexec PRIVATE
0035     ${kioexec_dbus_SRCS}
0036     main.cpp
0037 )
0038
0039 configure_file(config-kioexec.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kioexec.h)
0040
0041 target_link_libraries(kioexec
0042     Qt${QT_MAJOR_VERSION}::Widgets
0043     KF5::I18n
0044     KF5::KIOWidgets    # KRun
0045     KF5::WidgetsAddons # KMessageBox
0046     KF5::WindowSystem  # KStartupInfo
0047     KF5::DBusAddons    # KDBusService
0048  )
0049
0050 if (HAVE_X11)
0051     if (TARGET Qt5::X11Extras)
0052         target_link_libraries(kioexec Qt5::X11Extras)
0053     elseif (TARGET Qt6::Gui)
0054         target_link_libraries(kioexec Qt${QT_MAJOR_VERSION}::GuiPrivate) # qtx11extras_p.h
0055     endif()
0056 endif()
0057
0058 install(TARGETS kioexec DESTINATION ${KDE_INSTALL_LIBEXECDIR_KF} )
0059