src/filewidgets/CMakeLists.txt

0001 find_package(KF6Bookmarks ${KF_DEP_VERSION} REQUIRED)
0002
0003 configure_file(config-kiofilewidgets.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kiofilewidgets.h)
0004
0005 add_library(KF6KIOFileWidgets)
0006 add_library(KF6::KIOFileWidgets ALIAS KF6KIOFileWidgets)
0007
0008 set_target_properties(KF6KIOFileWidgets PROPERTIES
0009     VERSION     ${KIO_VERSION}
0010     SOVERSION   ${KIO_SOVERSION}
0011     EXPORT_NAME KIOFileWidgets
0012 )
0013
0014 target_sources(KF6KIOFileWidgets PRIVATE
0015   kfilemetapreview.cpp
0016   kimagefilepreview.cpp
0017   kpreviewwidgetbase.cpp
0018   defaultviewadapter.cpp
0019
0020   kdiroperator.cpp
0021   kdiroperatordetailview.cpp
0022   kdiroperatoriconview.cpp
0023   kdirsortfilterproxymodel.cpp #used in combination with kdirmodel.cpp
0024   kencodingfiledialog.cpp
0025   kfilebookmarkhandler.cpp
0026   kfilecopytomenu.cpp
0027   kfilecustomdialog.cpp
0028   kfilefiltercombo.cpp
0029   kfilewidget.cpp
0030   kfilewidgetdocktitlebar.cpp
0031   kfileplacesitem.cpp
0032   kfileplacesmodel.cpp
0033   kfileplacesview.cpp
0034   kfileplaceeditdialog.cpp
0035   kfilepreviewgenerator.cpp
0036   knameandurlinputdialog.cpp
0037   knewfilemenu.cpp
0038   kurlnavigatordropdownbutton.cpp
0039   kurlnavigatorbuttonbase.cpp
0040   kurlnavigatorbutton.cpp
0041   kurlnavigatorplacesselector.cpp
0042   kurlnavigatorschemecombo.cpp
0043   kurlnavigatortogglebutton.cpp
0044   kurlnavigator.cpp
0045   kurlnavigatormenu.cpp
0046   kurlnavigatorpathselectoreventfilter.cpp
0047
0048   ../new_file_templates/templates.qrc
0049 )
0050
0051
0052 ecm_qt_export_logging_category(
0053     IDENTIFIER KFILEWIDGETS_LOG
0054     CATEGORY_NAME kf.kio.filewidgets
0055     OLD_CATEGORY_NAMES kf5.kio.filewidgets
0056     DESCRIPTION "KFileWidgets (KIO)"
0057     EXPORT KIO
0058 )
0059
0060 ecm_qt_export_logging_category(
0061     IDENTIFIER KIO_KFILEWIDGETS_FW
0062     CATEGORY_NAME kf.kio.filewidgets.kfilewidget
0063     OLD_CATEGORY_NAMES kf5.kio.filewidgets.kfilewidget
0064     DEFAULT_SEVERITY Info
0065     DESCRIPTION "KFileWidgets (KIO)"
0066     EXPORT KIO
0067 )
0068
0069 ecm_qt_declare_logging_category(KF6KIOFileWidgets
0070     HEADER kfilefiltercombo_debug.h
0071     IDENTIFIER KIO_KFILEWIDGETS_KFILEFILTERCOMBO
0072     CATEGORY_NAME kf.kio.filewidgets.kfilefiltercombo
0073     OLD_CATEGORY_NAMES kf5.kio.filewidgets.kfilefiltercombo
0074     DEFAULT_SEVERITY Warning
0075     DESCRIPTION "KFileFilterCombo (KIO)"
0076     EXPORT KIO
0077 )
0078
0079 ecm_generate_export_header(KF6KIOFileWidgets
0080     BASE_NAME KIOFileWidgets
0081     GROUP_BASE_NAME KF
0082     VERSION ${KF_VERSION}
0083     USE_VERSION_HEADER
0084     VERSION_BASE_NAME KIO
0085     DEPRECATED_BASE_VERSION 0
0086     DEPRECATION_VERSIONS
0087     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0088 )
0089
0090 target_include_directories(KF6KIOFileWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIOFileWidgets>")
0091
0092 target_link_libraries(KF6KIOFileWidgets
0093   PUBLIC
0094     KF6::KIOWidgets
0095     KF6::Bookmarks    # in KFilePlacesModel's API
0096     KF6::ItemViews     # kdirsortfilterproxymodel
0097     KF6::Solid         # KFilePlacesModel/KFilePlacesView
0098   PRIVATE
0099     Qt6::Core5Compat
0100     KF6::GuiAddons    # KIconUtils
0101     KF6::IconThemes   # KIconLoader
0102     KF6::IconWidgets   # KIconButton
0103     KF6::I18n
0104     KF6::ConfigGui
0105     KF6::ConfigWidgets
0106     KF6::BookmarksWidgets
0107 )
0108
0109 ecm_generate_headers(KIOFileWidgets_HEADERS
0110   HEADER_NAMES
0111   KAbstractViewAdapter
0112   KImageFilePreview
0113   KPreviewWidgetBase
0114   KDirOperator
0115   KDirSortFilterProxyModel
0116   KFileCopyToMenu
0117   KFileCustomDialog
0118   KFileFilterCombo
0119   KFilePlaceEditDialog
0120   KFilePlacesModel
0121   KFilePlacesView
0122   KFilePreviewGenerator
0123   KFileWidget
0124   KUrlNavigator
0125   KNewFileMenu
0126   KNameAndUrlInputDialog
0127   KEncodingFileDialog
0128
0129   REQUIRED_HEADERS KIOFileWidgets_HEADERS
0130 )
0131
0132 install(TARGETS KF6KIOFileWidgets EXPORT KF6KIOTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0133
0134 install(FILES
0135   ${KIOFileWidgets_HEADERS}
0136   ${CMAKE_CURRENT_BINARY_DIR}/kiofilewidgets_export.h
0137   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOFileWidgets COMPONENT Devel)
0138
0139 # make available to ecm_add_qch in parent folder
0140 set(KIOFileWidgets_QCH_SOURCES ${KIOFileWidgets_HEADERS} PARENT_SCOPE)
0141