kio/src/CMakeLists.txt

0001 add_subdirectory(core)
0002
0003 # KIOCore-only executables
0004 if (NOT ANDROID)
0005     add_subdirectory(kioworkers)
0006     add_subdirectory(kiod)
0007     add_subdirectory(kssld)
0008     add_subdirectory(schemehandlers)
0009 endif()
0010 add_subdirectory(kioworker)
0011
0012 if (NOT KIOCORE_ONLY)
0013 add_subdirectory(gui)
0014 add_subdirectory(widgets)
0015 if (NOT ANDROID)
0016     add_subdirectory(kpasswdserver)
0017     add_subdirectory(filewidgets)
0018     add_subdirectory(kioexec)
0019     add_subdirectory(urifilters)
0020 endif()
0021
0022 if(NOT WIN32 AND NOT ANDROID)
0023   # arpa/nameser.h
0024   add_subdirectory(kpac)
0025 endif()
0026
0027 set(NON_KIOCORE_LINK_QCHS
0028     Qt6Widgets_QCH
0029     Qt6Network_QCH
0030     KF6Completion_QCH
0031     KF6WidgetsAddons_QCH
0032     KF6JobWidgets_QCH
0033     KF6Bookmarks_QCH
0034     KF6ItemViews_QCH
0035     KF6Solid_QCH
0036     KF6WindowSystem_QCH
0037 )
0038
0039 if(BUILD_DESIGNERPLUGIN AND NOT ANDROID)
0040     add_subdirectory(designer)
0041 endif()
0042
0043 endif()
0044
0045 ecm_qt_install_logging_categories(
0046     EXPORT KIO
0047     FILE kio.categories
0048     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0049 )
0050
0051 if (BUILD_QCH)
0052     macro(_make_absolute var_name base_path)
0053         set(_result)
0054         foreach(_path ${${var_name}})
0055             if(IS_ABSOLUTE "${_path}")
0056                 list(APPEND _result "${_path}")
0057             else()
0058                 list(APPEND _result "${base_path}/${_path}")
0059             endif()
0060         endforeach()
0061         set(${var_name} ${_result})
0062     endmacro()
0063
0064     _make_absolute(KIOCore_QCH_SOURCES "${CMAKE_CURRENT_SOURCE_DIR}/core")
0065     _make_absolute(KIOGui_QCH_SOURCES "${CMAKE_CURRENT_SOURCE_DIR}/gui")
0066     _make_absolute(KIOWidgets_QCH_SOURCES "${CMAKE_CURRENT_SOURCE_DIR}/widgets")
0067     _make_absolute(KIOFileWidgets_QCH_SOURCES "${CMAKE_CURRENT_SOURCE_DIR}/filewidgets")
0068
0069     ecm_add_qch(
0070         KF6KIO_QCH
0071         NAME KIO
0072         BASE_NAME KF6KIO
0073         VERSION ${KF_VERSION}
0074         ORG_DOMAIN org.kde
0075         SOURCES # using only public headers, to cover only public API
0076             ${KIOCore_QCH_SOURCES}
0077             ${KIOGui_QCH_SOURCES}
0078             ${KIOWidgets_QCH_SOURCES}
0079             ${KIOFileWidgets_QCH_SOURCES}
0080         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0081         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0082         LINK_QCHS
0083             KF6CoreAddons_QCH
0084             KF6Service_QCH
0085             ${NON_KIOCORE_LINK_QCHS}
0086         BLANK_MACROS
0087             KIOCORE_EXPORT
0088             KIOCORE_DEPRECATED_EXPORT
0089             KIOCORE_DEPRECATED
0090             "KIOCORE_DEPRECATED_VERSION(x, y, t)"
0091             "KIOCORE_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0092             "KIOCORE_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0093             "KIOCORE_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0094             KIOGUI_EXPORT
0095             KIOGUI_DEPRECATED_EXPORT
0096             KIOGUI_DEPRECATED
0097             "KIOGUI_DEPRECATED_VERSION(x, y, t)"
0098             "KIOGUI_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t))"
0099             "KIOGUI_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0100             "KIOGUI_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t))"
0101             KIOWIDGETS_EXPORT
0102             KIOWIDGETS_DEPRECATED_EXPORT
0103             KIOWIDGETS_DEPRECATED
0104             "KIOWIDGETS_DEPRECATED_VERSION(x, y, t)"
0105             "KIOWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0106             "KIOWIDGETS_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0107             "KIOWIDGETS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0108             KIOFILEWIDGETS_EXPORT
0109             KIOFILEWIDGETS_DEPRECATED_EXPORT
0110             KIOFILEWIDGETS_DEPRECATED
0111             "KIOFILEWIDGETS_DEPRECATED_VERSION(x, y, t)"
0112             "KIOFILEWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t))"
0113             "KIOFILEWIDGETS_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0114             "KIOFILEWIDGETS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t))"
0115         PREDEFINED_MACROS
0116             "KIOCORE_ENABLE_DEPRECATED_SINCE(x, y)=1"
0117             "KIOCORE_BUILD_DEPRECATED_SINCE(x, y)=1"
0118             "KIOGUI_ENABLE_DEPRECATED_SINCE(x, y)=1"
0119             "KIOGUI_BUILD_DEPRECATED_SINCE(x, y)=1"
0120             "KIOWIDGETS_ENABLE_DEPRECATED_SINCE(x, y)=1"
0121             "KIOWIDGETS_BUILD_DEPRECATED_SINCE(x, y)=1"
0122             "KIOFILEWIDGETS_ENABLE_DEPRECATED_SINCE(x, y)=1"
0123             "KIOFILEWIDGETS_BUILD_DEPRECATED_SINCE(x, y)=1"
0124         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0125         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0126         COMPONENT Devel
0127     )
0128 endif()