frameworks/kio/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0005
0006 project(KIO VERSION ${KF_VERSION})
0007
0008 include(FeatureSummary)
0009 find_package(ECM 5.106.0 NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake )
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019 include(KDEPackageAppTemplates)
0020
0021 include(ECMGenerateExportHeader)
0022 include(ECMMarkAsTest)
0023 include(ECMSetupVersion)
0024 include(ECMGenerateHeaders)
0025 include(ECMAddQch)
0026 include(ECMMarkNonGuiExecutable)
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMSourceVersionControl)
0029 include(ECMDeprecationSettings)
0030
0031 ecm_setup_version(
0032   PROJECT
0033   VARIABLE_PREFIX KIO
0034   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kio_version.h"
0035   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5KIOConfigVersion.cmake"
0036   SOVERSION 5)
0037
0038 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0039
0040 option(KIOCORE_ONLY "Only compile KIOCore, not KIOWidgets or anything that depends on it. This will disable support for cookies and passwordhandling (prompting and storing)." OFF)
0041
0042 # Enable state assertion by default on Jenkins and from-git builds.
0043 # This option should eventually be dropped and always be enabled.
0044 set(ASSERT_SLAVE_STATES_DEFAULT OFF)
0045 if(DEFINED ENV{JENKINS_SERVER_COOKIE} OR ECM_SOURCE_UNDER_VERSION_CONTROL)
0046     set(ASSERT_SLAVE_STATES_DEFAULT ON)
0047 endif()
0048 option(KIO_ASSERT_SLAVE_STATES
0049     "Used to control whether worker state assertions are enabled. When not enabled only warnings are generated."
0050     ${ASSERT_SLAVE_STATES_DEFAULT})
0051
0052 # TODO KF6: remove
0053 option(KIO_NO_PUBLIC_QTCONCURRENT "Privatize QtConcurrent linking, so KIO does not provide the target to revdeps.")
0054
0055 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0056 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0057
0058 option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON)
0059 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0060
0061 option(USE_FTPD_WSGIDAV_UNITTEST "Use ftpd Ruby Gem (for ftptest) and wsgidav Python module (for webdavtest) in unittests. Note that this is a temporary option that will be removed when distros add those packages in their repos." OFF)
0062
0063 find_package(KF5Archive ${KF_DEP_VERSION} REQUIRED)
0064 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0065 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0066 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0067 find_package(KF5Service ${KF_DEP_VERSION} REQUIRED)
0068 find_package(KF5DocTools ${KF_DEP_VERSION})
0069 find_package(KF5Solid ${KF_DEP_VERSION} REQUIRED) # for kio_trash
0070 if (NOT ANDROID)
0071     find_package(KF5Crash ${KF_DEP_VERSION} REQUIRED)
0072     find_package(KF5DBusAddons ${KF_DEP_VERSION} REQUIRED)
0073 endif()
0074
0075 if (NOT KIOCORE_ONLY)
0076 find_package(KF5Bookmarks ${KF_DEP_VERSION} REQUIRED)
0077 find_package(KF5Completion ${KF_DEP_VERSION} REQUIRED)
0078 find_package(KF5ConfigWidgets ${KF_DEP_VERSION} REQUIRED)
0079 find_package(KF5GuiAddons ${KF_DEP_VERSION} REQUIRED)
0080 find_package(KF5IconThemes ${KF_DEP_VERSION} REQUIRED)
0081 find_package(KF5ItemViews ${KF_DEP_VERSION} REQUIRED)
0082 find_package(KF5JobWidgets ${KF_DEP_VERSION} REQUIRED)
0083 find_package(KF5WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0084 find_package(KF5WindowSystem ${KF_DEP_VERSION} REQUIRED)
0085
0086 find_package(KDED)
0087 set_package_properties(KDED PROPERTIES DESCRIPTION "Daemon providing session services"
0088                        TYPE RUNTIME
0089                        PURPOSE "KDED is used at runtime for proxy management and cookie storage"
0090                       )
0091 endif()
0092
0093 if (UNIX AND NOT ANDROID)
0094     find_package(KF5Auth ${KF_DEP_VERSION} REQUIRED)
0095 endif()
0096
0097 # tell what is missing without doctools
0098 set_package_properties(KF5DocTools PROPERTIES DESCRIPTION "Provides tools to generate documentation in various format from DocBook files"
0099                        TYPE OPTIONAL
0100                        PURPOSE "Required to build help KIO worker and documentation"
0101                       )
0102
0103 set(REQUIRED_QT_VERSION 5.15.2)
0104 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets Network Concurrent Xml Test)
0105 if (NOT ANDROID)
0106     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0107 endif()
0108
0109 set(_qt6_core_compat_found FALSE)
0110 if (QT_MAJOR_VERSION STREQUAL "6")
0111     find_package(Qt6Core5Compat ${REQUIRED_QT_VERSION} REQUIRED) # QTextCodec
0112     set(_qt6_core_compat_found ${Qt6Core5Compat_FOUND})
0113 endif()
0114
0115 find_package(GSSAPI)
0116 set_package_properties(GSSAPI PROPERTIES DESCRIPTION "Allows KIO to make use of certain HTTP authentication services"
0117                        URL "https://web.mit.edu/kerberos/www/"
0118                        TYPE OPTIONAL
0119                        PURPOSE "A MIT or HEIMDAL flavor of GSSAPI can be used"
0120                       )
0121
0122 if (NOT APPLE AND NOT WIN32 AND NOT ANDROID)
0123     option(WITH_X11 "Build with X11 integration" ON)
0124     if(WITH_X11)
0125         if (QT_MAJOR_VERSION STREQUAL "5")
0126             find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED X11Extras)
0127         else()
0128             # qtx11extras_p.h is in Qt6Gui, which is implied by the find_package(QtWidgets) above
0129         endif()
0130     endif()
0131     set(HAVE_X11 ${WITH_X11})
0132 endif()
0133
0134 find_package(ACL)
0135 set(HAVE_LIBACL ${ACL_FOUND})
0136 set(HAVE_POSIX_ACL ${ACL_FOUND})
0137 set_package_properties(ACL PROPERTIES DESCRIPTION "LibACL"
0138                        URL "ftp://oss.sgi.com/projects/xfs/cmd_tars"
0139                        TYPE RECOMMENDED
0140                        PURPOSE "Support for manipulating access control lists")
0141
0142 # Used by KMountPoint
0143 if (CMAKE_SYSTEM_NAME MATCHES "Linux")
0144     find_package(LibMount REQUIRED)
0145     set(HAVE_LIB_MOUNT ${LibMount_FOUND})
0146 endif()
0147
0148 if (ANDROID)
0149     # used to mark code that is just stubbed out on Android for now
0150     # and that would still need a decision on how to deal with that
0151     add_definitions(-DKIO_ANDROID_STUB)
0152 endif()
0153
0154 ecm_set_disabled_deprecation_versions(
0155     QT 5.15.2
0156     KF 5.97
0157     KCOMPLETION 5.65 # we use KPixmapProvider in public API
0158     KSERVICE 5.81 # we use KMimeTypeTrader in KFileItemActions
0159     KCOREADDONS 5.85 # KService::createInstance uses deprecated parts of KCoreAddons in the header
0160     KCONFIGCORE 5.81 # we use KDesktopFile::readDevice
0161     KWIDGETSADDONS 5.96 # we use KMessageDialog::Sorry
0162 )
0163
0164 add_definitions(-DTRANSLATION_DOMAIN=\"kio5\")
0165 ki18n_install(po)
0166
0167 if (KF5DocTools_FOUND)
0168     kdoctools_install(po)
0169 endif()
0170
0171 if (KF5DocTools_FOUND)
0172      add_subdirectory(docs)
0173 endif()
0174
0175 include(CheckLibraryExists)
0176 add_subdirectory(src)
0177
0178 if(BUILD_TESTING)
0179     add_subdirectory(autotests)
0180     if (NOT KIOCORE_ONLY)
0181         add_subdirectory(tests)
0182     endif()
0183 endif()
0184
0185 add_subdirectory(kconf_update)
0186 add_subdirectory(templates)
0187
0188 # create a Config.cmake and a ConfigVersion.cmake file and install them
0189 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5KIO")
0190
0191 if (BUILD_QCH)
0192     ecm_install_qch_export(
0193         TARGETS KF5KIO_QCH
0194         FILE KF5KIOQchTargets.cmake
0195         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0196         COMPONENT Devel
0197     )
0198     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5KIOQchTargets.cmake\")")
0199 endif()
0200
0201 include(CMakePackageConfigHelpers)
0202
0203 configure_package_config_file(
0204   "${CMAKE_CURRENT_SOURCE_DIR}/KF5KIOConfig.cmake.in"
0205   "${CMAKE_CURRENT_BINARY_DIR}/KF5KIOConfig.cmake"
0206   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0207   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0208 )
0209
0210 install(FILES
0211   "${CMAKE_CURRENT_BINARY_DIR}/KF5KIOConfig.cmake"
0212   "${CMAKE_CURRENT_BINARY_DIR}/KF5KIOConfigVersion.cmake"
0213   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0214   COMPONENT Devel
0215 )
0216
0217 install(EXPORT KF5KIOTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5KIOTargets.cmake NAMESPACE KF5:: )
0218
0219 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/src/kio_version.h
0220         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIO COMPONENT Devel)
0221
0222 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0223
0224 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)