src/kdeinit/CMakeLists.txt

0001 # on win32 kdeinit5 has to be a console application
0002 # to be able to catch stderr based --verbose output
0003 add_executable(kdeinit5)
0004 ecm_mark_nongui_executable(kdeinit5)
0005
0006 if (WIN32)
0007     target_sources(kdeinit5 PRIVATE kinit_win.cpp ../klauncher_cmds.cpp)
0008     target_link_libraries(kdeinit5 psapi)
0009 elseif (APPLE)
0010     target_sources(kdeinit5 PRIVATE kinit.cpp kinit.h kinit_mac.mm proctitle.cpp ../klauncher_cmds.cpp)
0011 else ()
0012     target_sources(kdeinit5 PRIVATE kinit.cpp kinit.h proctitle.cpp ../klauncher_cmds.cpp)
0013 endif ()
0014
0015 target_include_directories(kdeinit5 PRIVATE ${KInit_BINARY_DIR}) # for kinit_version.h
0016
0017 target_link_libraries(kdeinit5
0018     ${KINIT_SOCKET_LIBRARY}
0019     Qt5::Gui #QFont::initialize
0020     KF5::WindowSystem # KStartupInfo
0021     KF5::Crash # KCrash::loadedByKdeinit
0022     KF5::I18n #i18n() used on some error messages
0023     KF5::ConfigCore
0024     Qt5::DBus
0025 )
0026
0027 if (NOT WIN32)
0028     target_link_libraries(kdeinit5 KF5::DBusAddons)
0029 endif()
0030
0031 if (APPLE)
0032     target_link_libraries(kdeinit5 "-framework Foundation -framework AppKit")
0033 endif ()
0034
0035 target_compile_definitions(kdeinit5 PRIVATE
0036     CMAKE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
0037     KDE_INSTALL_LIBDIR="${KDE_INSTALL_LIBDIR}"
0038     KDE_INSTALL_FULL_LIBEXECDIR_KF5="${KDE_INSTALL_FULL_LIBEXECDIR_KF5}"
0039 )
0040
0041 if (HAVE_X11)
0042   target_link_libraries(kdeinit5 ${X11_X11_LIB})
0043 endif()
0044
0045 if (HAVE_XCB)
0046   target_link_libraries(kdeinit5 XCB::XCB)
0047 endif()
0048
0049 install(TARGETS kdeinit5 ${KF5_INSTALL_TARGETS_DEFAULT_ARGS} )
0050
0051 if (NOT WIN32)
0052   # kdeinit5_shutdown
0053   add_executable(kdeinit5_shutdown ../wrapper.cpp)
0054   ecm_mark_nongui_executable(kdeinit5_shutdown)
0055
0056   target_link_libraries(kdeinit5_shutdown  ${KINIT_SOCKET_LIBRARY} Qt5::Core KF5::DBusAddons)
0057
0058   install(TARGETS kdeinit5_shutdown ${KF5_INSTALL_TARGETS_DEFAULT_ARGS} )
0059
0060   # kdeinit5_wrapper
0061   add_executable(kdeinit5_wrapper ../wrapper.cpp)
0062   ecm_mark_nongui_executable(kdeinit5_wrapper)
0063
0064   target_link_libraries(kdeinit5_wrapper  ${KINIT_SOCKET_LIBRARY} Qt5::Core KF5::DBusAddons)
0065
0066   if (NOT HAVE_X11)
0067     target_compile_definitions(kdeinit5_wrapper PRIVATE -DNO_DISPLAY)
0068   endif ()
0069
0070   install(TARGETS kdeinit5_wrapper ${KF5_INSTALL_TARGETS_DEFAULT_ARGS} )
0071 endif ()