frameworks/kinit/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0005 project(KInit VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.106.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(ECMSetupVersion)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMDeprecationSettings)
0021 include(ConfigureChecks.cmake)
0022
0023 set(REQUIRED_QT_VERSION 5.15.2)
0024 find_package(Qt5 "${REQUIRED_QT_VERSION}" CONFIG REQUIRED Core Gui DBus)
0025
0026 ecm_setup_version(PROJECT VARIABLE_PREFIX KINIT
0027                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kinit_version.h"
0028                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5InitConfigVersion.cmake"
0029                         SOVERSION 5)
0030
0031 #optional features
0032 if (NOT APPLE AND NOT WIN32)
0033     option(WITH_X11 "Build with X11 integration" ON)
0034     if(WITH_X11)
0035         find_package(X11 REQUIRED)
0036         set(HAVE_X11 1)
0037
0038         find_package(XCB MODULE COMPONENTS XCB)
0039         set_package_properties(XCB PROPERTIES TYPE OPTIONAL)
0040         set(HAVE_XCB ${XCB_XCB_FOUND})
0041     endif()
0042 endif()
0043
0044 # used by 4 executables in this module
0045 if(HAVE_SOCKET_LIBRARY)
0046   set(KINIT_SOCKET_LIBRARY socket)
0047 else()
0048   set(KINIT_SOCKET_LIBRARY)
0049 endif()
0050
0051 find_package(KF5Service ${KF_DEP_VERSION} REQUIRED)
0052 find_package(KF5KIO ${KF_DEP_VERSION} REQUIRED)
0053 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0054 find_package(KF5WindowSystem ${KF_DEP_VERSION} REQUIRED)
0055 find_package(KF5Crash ${KF_DEP_VERSION} REQUIRED)
0056 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0057 find_package(KF5DocTools ${KF_DEP_VERSION})
0058
0059 if (NOT WIN32)
0060 find_package(Libcap)
0061 find_package(KF5DBusAddons ${KF_DEP_VERSION} REQUIRED)
0062 set_package_properties(Libcap PROPERTIES
0063                        TYPE OPTIONAL
0064                        PURPOSE "KInit needs setcap in order to install start_kdeinit with CAP_SYS_RESOURCE capabilities"
0065                       )
0066 endif ()
0067 set(HAVE_CAPABILITIES ${Libcap_FOUND})
0068
0069 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Init")
0070 configure_package_config_file(
0071   "${CMAKE_CURRENT_SOURCE_DIR}/KF5InitConfig.cmake.in"
0072   "${CMAKE_CURRENT_BINARY_DIR}/KF5InitConfig.cmake"
0073   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0074   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0075 )
0076
0077 add_definitions(-DTRANSLATION_DOMAIN=\"kinit5\")
0078
0079 ecm_set_disabled_deprecation_versions(
0080     QT 5.15.2
0081     KF 5.95
0082     KCOREADDONS 5.85 # KPluginLoader::fileName
0083 )
0084
0085 ki18n_install(po)
0086
0087 if (KF5DocTools_FOUND)
0088     kdoctools_install(po)
0089 endif()
0090 add_subdirectory(src)
0091
0092 if (KF5DocTools_FOUND)
0093     add_subdirectory(docs)
0094 endif()
0095
0096 install( FILES
0097         "${CMAKE_CURRENT_BINARY_DIR}/KF5InitConfig.cmake"
0098     KF5InitMacros.cmake ${CMAKE_CURRENT_BINARY_DIR}/KF5InitConfigVersion.cmake
0099     DESTINATION ${CMAKECONFIG_INSTALL_DIR} COMPONENT Devel )
0100
0101 install(FILES
0102         kde5init_dummy.cpp.in
0103         DESTINATION ${CMAKECONFIG_INSTALL_DIR} COMPONENT Devel)
0104
0105 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)