src/localedata/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021 Volker Krause <vkrause@kde.org>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config-localedata.h.in" "${CMAKE_CURRENT_BINARY_DIR}/config-localedata.h")
0005
0006 add_library(KF5I18nLocaleData)
0007 add_library(KF5::I18nLocaleData ALIAS KF5I18nLocaleData)
0008
0009 target_sources(KF5I18nLocaleData PRIVATE
0010     isocodes.cpp
0011     isocodescache.cpp
0012     kcountry.cpp
0013     kcountrysubdivision.cpp
0014     ktimezone.cpp
0015     spatial_index.cpp
0016     spatial_index_entry.cpp
0017     spatial_index_property.cpp
0018     timezonedata.cpp
0019 )
0020
0021 ecm_generate_export_header(KF5I18nLocaleData
0022     BASE_NAME KI18nLocaleData
0023     GROUP_BASE_NAME KF
0024     VERSION ${KF_VERSION}
0025     DEPRECATED_BASE_VERSION 0
0026     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0027 )
0028
0029 ecm_qt_declare_logging_category(KF5I18nLocaleData
0030     HEADER logging.h
0031     IDENTIFIER KI18NLD
0032     CATEGORY_NAME kf.i18n.localeData
0033     DESCRIPTION "KI18n Locale Data"
0034     EXPORT KI18N
0035 )
0036
0037 target_include_directories(KF5I18nLocaleData
0038     INTERFACE
0039         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KI18nLocaleData>"
0040         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KI18n>" # for version header
0041 )
0042
0043 target_link_libraries(KF5I18nLocaleData PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0044 target_link_libraries(KF5I18nLocaleData PRIVATE KF5I18n)
0045 if (TARGET Qt5::CorePrivate)
0046     target_link_libraries(KF5I18nLocaleData PRIVATE Qt5::CorePrivate) # private API no longer needed with Qt6
0047 endif()
0048 target_compile_options(KF5I18n PRIVATE -DTRANSLATION_DOMAIN=\"ki18n5\")
0049
0050 set_target_properties(KF5I18nLocaleData PROPERTIES
0051     VERSION ${KI18N_VERSION}
0052     SOVERSION ${KI18N_SOVERSION}
0053     EXPORT_NAME I18nLocaleData
0054 )
0055
0056 install(TARGETS KF5I18nLocaleData EXPORT KF5I18nTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0057
0058 ecm_generate_headers(KI18nLocaleData_HEADERS
0059   HEADER_NAMES
0060     KCountry
0061     KCountrySubdivision
0062     KTimeZone
0063     REQUIRED_HEADERS KI18nLocaleData_HEADERS
0064 )
0065
0066 install(FILES
0067     ${KI18nLocaleData_HEADERS}
0068     ${CMAKE_CURRENT_BINARY_DIR}/ki18nlocaledata_export.h
0069     DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KI18nLocaleData" COMPONENT Devel
0070 )