kholidays/src/CMakeLists.txt

0001 add_library(KF5Holidays)
0002 add_library(KF5::Holidays ALIAS KF5Holidays)
0003
0004 set_target_properties(KF5Holidays PROPERTIES
0005   VERSION     ${KHOLIDAYS_VERSION}
0006   SOVERSION   ${KHOLIDAYS_SOVERSION}
0007   EXPORT_NAME Holidays
0008 )
0009
0010 target_sources(KF5Holidays PRIVATE
0011     astroseasons.cpp
0012     astroseasons.h
0013     holiday.cpp
0014     holiday.h
0015     holiday_p.h
0016     holidayregion.cpp
0017     holidayregion.h
0018     lunarphase.cpp
0019     lunarphase.h
0020     parsers/holidayparserdriver.cpp
0021     parsers/holidayparserdriver_p.h
0022     parsers/plan2/FlexLexer.h
0023     parsers/plan2/holidayparserdriverplan.cpp
0024     parsers/plan2/holidayparserdriverplan_p.h
0025     parsers/plan2/holidayparserplan.cpp
0026     parsers/plan2/holidayscannerplan.cpp
0027     parsers/plan2/holidayscannerplan_p.h
0028     parsers/qcalendarsystem.cpp
0029     parsers/qcalendarsystem_p.h
0030     sunriseset.cpp
0031     sunriseset.h
0032     util.h
0033     zodiac.cpp
0034     zodiac.h
0035
0036   ../holidays/holidays.qrc
0037 )
0038
0039 ecm_create_qm_loader(KF5Holidays libkholidays5_qt)
0040
0041 ecm_qt_declare_logging_category(KF5Holidays
0042     HEADER kholidays_debug.h
0043     IDENTIFIER KHOLIDAYS_LOG
0044     CATEGORY_NAME kf.holidays
0045     DESCRIPTION "KHolidays"
0046     EXPORT KHOLIDAYS
0047 )
0048
0049 ecm_generate_export_header(KF5Holidays
0050     VERSION  ${KF_VERSION}
0051     BASE_NAME KHolidays
0052     GROUP_BASE_NAME KF
0053     DEPRECATED_BASE_VERSION 0
0054     DEPRECATION_VERSIONS 5.95
0055     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0056 )
0057
0058 target_include_directories(KF5Holidays INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KHolidays>")
0059 target_include_directories(KF5Holidays PUBLIC "$<BUILD_INTERFACE:${KHolidays_SOURCE_DIR}/src;${KHolidays_BINARY_DIR}/src>")
0060 target_include_directories(KF5Holidays PUBLIC "$<BUILD_INTERFACE:${KHolidays_SOURCE_DIR}/src/parsers/plan2>")
0061
0062 target_link_libraries(KF5Holidays PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0063
0064 ecm_generate_headers(KHolidays_CamelCase_HEADERS
0065   HEADER_NAMES
0066   AstroSeasons
0067   Holiday
0068   HolidayRegion
0069   LunarPhase
0070   SunRiseSet
0071   Zodiac
0072   PREFIX KHolidays
0073   REQUIRED_HEADERS KHolidays_HEADERS
0074 )
0075
0076 install(TARGETS KF5Holidays EXPORT KF5HolidaysTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0077
0078 ########### install files ###############
0079 install(FILES
0080   ${CMAKE_CURRENT_BINARY_DIR}/kholidays_export.h
0081   ${KHolidays_HEADERS}
0082   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KHolidays/kholidays
0083   COMPONENT Devel
0084 )
0085
0086 install(FILES
0087   ${KHolidays_CamelCase_HEADERS}
0088   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KHolidays/KHolidays
0089   COMPONENT Devel
0090 )
0091
0092 if(BUILD_QCH)
0093   ecm_add_qch(
0094     KF5Holidays_QCH
0095     NAME KHolidays
0096     BASE_NAME KF5Holidays
0097     VERSION ${KF_VERSION}
0098     ORG_DOMAIN org.kde
0099     SOURCES # using only public headers, to cover only public API
0100       ${KHolidays_HEADERS}
0101     MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0102     LINK_QCHS
0103       Qt${QT_MAJOR_VERSION}Core_QCH
0104     INCLUDE_DIRS
0105       ${CMAKE_CURRENT_BINARY_DIR}
0106     BLANK_MACROS
0107       KHOLIDAYS_EXPORT
0108     TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0109     QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110     COMPONENT Devel
0111   )
0112 endif()
0113
0114 ecm_generate_pri_file(
0115   BASE_NAME KHolidays
0116   LIB_NAME KF5Holidays
0117   DEPS "widgets"
0118   FILENAME_VAR PRI_FILENAME
0119   INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KHolidays
0120 )
0121
0122 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0123
0124 add_subdirectory(declarative)
0125
0126 ecm_qt_install_logging_categories(
0127     EXPORT KHOLIDAYS
0128     FILE kholidays.categories
0129     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0130 )