frameworks/kguiaddons/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.240.0") # handled by release scripts
0004 project(KGuiAddons VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.240.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016
0017 include(KDEGitCommitHooks)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020 include(ECMQtDeclareLoggingCategory)
0021 include(ECMDeprecationSettings)
0022 include(ECMAddQch)
0023 include(ECMGenerateExportHeader)
0024 include(ECMMarkNonGuiExecutable)
0025
0026 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0027 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0028 option(BUILD_GEO_SCHEME_HANDLER "Build the geo: URI scheme handler. Disable this if you are building two major versions for co-installability in the older variant." ON)
0029
0030 if (UNIX AND NOT ANDROID AND NOT APPLE)
0031     option(WITH_WAYLAND "Build with support for KModifierKeyInfo, KSystemClipboard and KKeySequenceRecorder inhibiting shortcuts on Wayland" ON)
0032     add_feature_info(WAYLAND ${WITH_WAYLAND} "KeySequenceEditor inhibiting shortcuts on Wayland")
0033
0034     option(WITH_X11 "Build with support for KModifierKeyInfo on X11" ON)
0035     add_feature_info(X11 ${WITH_X11} "KeySequenceEditor inhibiting shortcuts on X11")
0036
0037     option(WITH_DBUS "Build with support for color scheme information via XDG portals" ON)
0038
0039 else()
0040     set(WITH_WAYLAND OFF)
0041     set(WITH_X11 OFF)
0042     set(WITH_DBUS OFF)
0043 endif()
0044
0045 set(REQUIRED_QT_VERSION 6.5.0)
0046 if (WITH_WAYLAND)
0047     set(_qtgui_find_components COMPONENTS Private)
0048 endif()
0049 # QtGui must be found before Qt5WaylandClient
0050 find_package(Qt6Gui ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE ${_qtgui_find_components})
0051
0052 if (WITH_X11)
0053     find_package(X11 REQUIRED MODULE)
0054     find_package(XCB REQUIRED MODULE COMPONENTS XCB)
0055 endif()
0056
0057 if (WITH_WAYLAND)
0058     find_package(PlasmaWaylandProtocols 1.10.0 REQUIRED)
0059     find_package(Qt6WaylandClient ${REQUIRED_QT_VERSION} REQUIRED CONFIG)
0060     find_package(Wayland 1.9 REQUIRED Client)
0061 endif()
0062
0063 if (WITH_DBUS)
0064     find_package(Qt6DBus ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0065 endif()
0066
0067 set(kguiaddons_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kguiaddons_version.h")
0068 ecm_setup_version(PROJECT VARIABLE_PREFIX KGUIADDONS
0069                         VERSION_HEADER "${kguiaddons_version_header}"
0070                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6GuiAddonsConfigVersion.cmake"
0071                         SOVERSION 6)
0072
0073 ecm_set_disabled_deprecation_versions(
0074     QT 6.4
0075 )
0076
0077 add_subdirectory(src)
0078 if (BUILD_TESTING)
0079     add_subdirectory(autotests)
0080     add_subdirectory(tests)
0081 endif()
0082
0083 # create a Config.cmake and a ConfigVersion.cmake file and install them
0084 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6GuiAddons")
0085
0086 if (BUILD_QCH)
0087     ecm_install_qch_export(
0088         TARGETS KF6GuiAddons_QCH
0089         FILE KF6GuiAddonsQchTargets.cmake
0090         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0091         COMPONENT Devel
0092     )
0093     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6GuiAddonsQchTargets.cmake\")")
0094 endif()
0095
0096 include(CMakePackageConfigHelpers)
0097
0098 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6GuiAddonsConfig.cmake.in"
0099                               "${CMAKE_CURRENT_BINARY_DIR}/KF6GuiAddonsConfig.cmake"
0100                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0101                               )
0102
0103 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6GuiAddonsConfig.cmake"
0104                "${CMAKE_CURRENT_BINARY_DIR}/KF6GuiAddonsConfigVersion.cmake"
0105         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0106         COMPONENT Devel )
0107
0108
0109 install(EXPORT KF6GuiAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0110         FILE KF6GuiAddonsTargets.cmake NAMESPACE KF6:: COMPONENT Devel)
0111
0112
0113 install(FILES ${kguiaddons_version_header}
0114         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KGuiAddons COMPONENT Devel)
0115
0116 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0117
0118 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)