src/runtime/CMakeLists.txt

0001 ###############################################################################
0002 ### KDED Global Accel Daemon
0003
0004 set(kglobalaccelprivate_SRCS
0005     kglobalacceld.cpp
0006     kglobalaccel_interface.cpp
0007     kserviceactioncomponent.cpp
0008     component.cpp
0009     logging.cpp
0010     globalshortcut.cpp
0011     globalshortcutsregistry.cpp
0012     globalshortcutcontext.cpp
0013     ../sequencehelpers_p.cpp
0014 )
0015 ecm_create_qm_loader(kglobalaccelprivate_SRCS kglobalaccel5_qt)
0016
0017 configure_file(config-kglobalaccel.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kglobalaccel.h )
0018
0019 add_library(KF5GlobalAccelPrivate ${kglobalaccelprivate_SRCS})
0020 add_library(KF5::GlobalAccelPrivate ALIAS KF5GlobalAccelPrivate)
0021 ecm_generate_export_header(KF5GlobalAccelPrivate
0022     EXPORT_FILE_NAME kf5globalaccelprivate_export.h
0023     BASE_NAME KGlobalAccelPrivate
0024     GROUP_BASE_NAME KF
0025     VERSION ${KF_VERSION}
0026     DEPRECATED_BASE_VERSION 0
0027     DEPRECATION_VERSIONS 4.3 5.90
0028     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0029 )
0030
0031 target_include_directories(KF5GlobalAccelPrivate INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel>")
0032
0033 target_link_libraries(KF5GlobalAccelPrivate
0034     PUBLIC
0035         Qt${QT_MAJOR_VERSION}::DBus
0036         KF5::GlobalAccel
0037         KF5::WindowSystem # KKeyServer
0038         KF5::CoreAddons   # KAboutData
0039         KF5::ConfigCore
0040 )
0041
0042 set_target_properties(KF5GlobalAccelPrivate PROPERTIES VERSION ${KGLOBALACCEL_VERSION}
0043                                                 SOVERSION ${KGLOBALACCEL_SOVERSION}
0044                                                 EXPORT_NAME "GlobalAccelPrivate"
0045 )
0046
0047 if(XCB_XCB_FOUND)
0048     if (TARGET Qt5::X11Extras)
0049         target_link_libraries(KF5GlobalAccelPrivate PUBLIC Qt5::X11Extras)
0050     elseif (TARGET Qt6::Gui)
0051         target_link_libraries(KF5GlobalAccelPrivate PUBLIC Qt6::GuiPrivate) # qtx11extras_p.h
0052     endif()
0053 endif()
0054
0055 if (NOT KF6_COMPAT_BUILD)
0056     add_executable(kglobalaccel5 main.cpp logging.cpp)
0057     ecm_mark_nongui_executable(kglobalaccel5)
0058
0059     target_include_directories(kglobalaccel5 PRIVATE ${CMAKE_BINARY_DIR})
0060
0061     target_link_libraries(kglobalaccel5
0062         KF5GlobalAccelPrivate
0063         KF5::DBusAddons   # KDBusService
0064         KF5::Crash
0065         )
0066
0067     add_subdirectory(plugins)
0068
0069     if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.102.0)
0070         install( FILES kglobalaccel.desktop  DESTINATION ${KDE_INSTALL_KSERVICESDIR} RENAME kglobalaccel5.desktop)
0071     endif()
0072
0073     install( TARGETS kglobalaccel5 ${KF_INSTALL_TARGETS_DEFAULT_ARGS} )
0074
0075
0076     # D-Bus activation service file, and associated systemd service
0077     include (ECMGenerateDBusServiceFile)
0078     include (ECMConfiguredInstall)
0079     ecm_generate_dbus_service_file(
0080         NAME org.kde.kglobalaccel
0081         EXECUTABLE "${KDE_INSTALL_FULL_BINDIR}/kglobalaccel5"
0082         SYSTEMD_SERVICE plasma-kglobalaccel.service
0083         DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR}
0084     )
0085
0086     ecm_install_configured_files(
0087         INPUT plasma-kglobalaccel.service.in
0088         DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR}
0089     )
0090 endif()
0091
0092 # Install application and configuration
0093 install(TARGETS KF5GlobalAccelPrivate EXPORT KF5GlobalAccelTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0094
0095 install(FILES
0096   ${CMAKE_CURRENT_BINARY_DIR}/kf5globalaccelprivate_export.h
0097   kglobalacceld.h
0098   kglobalaccel_interface.h
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel/private COMPONENT Devel
0100 )