kglobalaccel/src/CMakeLists.txt

0001 configure_file(config-kglobalaccel.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kglobalaccel.h )
0002
0003 set(kglobalaccel_SRCS
0004   kglobalaccel.cpp
0005   kglobalshortcutinfo.cpp
0006   kglobalshortcutinfo_dbus.cpp
0007 )
0008 ecm_qt_declare_logging_category(kglobalaccel_SRCS
0009     HEADER kglobalaccel_debug.h
0010     IDENTIFIER KGLOBALACCEL_LOG
0011     CATEGORY_NAME kf.globalaccel
0012     OLD_CATEGORY_NAMES kf5.kglobalaccel
0013     DESCRIPTION "KGlobalAccel"
0014     EXPORT KGLOBALACCEL
0015 )
0016
0017 ecm_qt_export_logging_category(
0018     IDENTIFIER KGLOBALACCELD
0019     CATEGORY_NAME kf.globalaccel.kglobalacceld
0020     OLD_CATEGORY_NAMES kglobalaccel-runtime
0021     DESCRIPTION "KGlobalAccel demon"
0022     EXPORT KGLOBALACCEL
0023 )
0024
0025 ecm_create_qm_loader(kglobalaccel_SRCS kglobalaccel5_qt)
0026
0027 set(kglobalaccel_xml ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.KGlobalAccel.xml)
0028 set_source_files_properties(${kglobalaccel_xml} PROPERTIES INCLUDE "kglobalshortcutinfo_p.h")
0029 qt_add_dbus_interface(kglobalaccel_SRCS ${kglobalaccel_xml} kglobalaccel_interface )
0030 install(FILES ${kglobalaccel_xml} DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR} RENAME kf5_org.kde.KGlobalAccel.xml)
0031
0032 set(kglobalaccel_component_xml ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.kglobalaccel.Component.xml)
0033 set_source_files_properties(${kglobalaccel_component_xml} PROPERTIES INCLUDE "kglobalshortcutinfo_p.h")
0034 qt_add_dbus_interface(kglobalaccel_SRCS ${kglobalaccel_component_xml} kglobalaccel_component_interface )
0035 install(FILES ${kglobalaccel_component_xml} DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR} RENAME kf5_org.kde.kglobalaccel.Component.xml)
0036
0037 add_library(KF5GlobalAccel ${kglobalaccel_SRCS})
0038 add_library(KF5::GlobalAccel ALIAS KF5GlobalAccel)
0039 ecm_generate_export_header(KF5GlobalAccel
0040     BASE_NAME KGlobalAccel
0041     GROUP_BASE_NAME KF
0042     VERSION ${KF_VERSION}
0043     DEPRECATED_BASE_VERSION 0
0044     DEPRECATION_VERSIONS 4.2 4.4 5.9 5.90 5.102
0045     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0046 )
0047
0048 target_include_directories(KF5GlobalAccel INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel>")
0049
0050 target_link_libraries(KF5GlobalAccel
0051 PUBLIC
0052     Qt${QT_MAJOR_VERSION}::DBus
0053     Qt${QT_MAJOR_VERSION}::Widgets
0054 )
0055
0056 if(HAVE_X11)
0057     if (TARGET Qt5::X11Extras)
0058         target_link_libraries(KF5GlobalAccel PRIVATE Qt5::X11Extras)
0059     elseif (TARGET Qt6::Gui)
0060         target_link_libraries(KF5GlobalAccel PRIVATE Qt6::GuiPrivate) # qtx11extras_p.h
0061     endif()
0062 endif()
0063
0064 set_target_properties(KF5GlobalAccel PROPERTIES VERSION   ${KGLOBALACCEL_VERSION}
0065                                                 SOVERSION ${KGLOBALACCEL_SOVERSION}
0066                                                 EXPORT_NAME "GlobalAccel"
0067 )
0068
0069 ecm_generate_headers(KGlobalAccel_HEADERS
0070   HEADER_NAMES
0071   KGlobalAccel
0072   KGlobalShortcutInfo
0073
0074   REQUIRED_HEADERS KGlobalAccel_HEADERS
0075 )
0076
0077 install(TARGETS KF5GlobalAccel EXPORT KF5GlobalAccelTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0078
0079 install(FILES
0080   ${CMAKE_CURRENT_BINARY_DIR}/kglobalaccel_export.h
0081   ${KGlobalAccel_HEADERS}
0082   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel COMPONENT Devel
0083 )
0084
0085 if(BUILD_QCH)
0086     ecm_add_qch(
0087         KF5GlobalAccel_QCH
0088         NAME KGlobalAccel
0089         BASE_NAME KF5GlobalAccel
0090         VERSION ${KF_VERSION}
0091         ORG_DOMAIN org.kde
0092         SOURCES # using only public headers, to cover only public API
0093             ${KGlobalAccel_HEADERS}
0094         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0095         LINK_QCHS
0096             Qt5Widgets_QCH
0097             Qt5DBus_QCH
0098         INCLUDE_DIRS
0099             ${CMAKE_CURRENT_BINARY_DIR}
0100         BLANK_MACROS
0101             KGLOBALACCEL_EXPORT
0102             KGLOBALACCEL_DEPRECATED
0103             KGLOBALACCEL_DEPRECATED_EXPORT
0104             "KGLOBALACCEL_DEPRECATED_VERSION(x, y, t)"
0105         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0106         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0107         COMPONENT Devel
0108     )
0109 endif()
0110
0111 include(ECMGeneratePriFile)
0112 ecm_generate_pri_file(BASE_NAME KGlobalAccel LIB_NAME KF5GlobalAccel DEPS "dbus widgets" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel)
0113 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0114
0115 if (BUILD_RUNTIME)
0116     add_subdirectory(runtime)
0117 endif()
0118
0119 ecm_qt_install_logging_categories(
0120     EXPORT KGLOBALACCEL
0121     FILE kglobalaccel.categories
0122     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0123 )