frameworks/kglobalaccel/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KGlobalAccel VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.249.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019
0020 include(ECMGenerateExportHeader)
0021 include(CMakePackageConfigHelpers)
0022 include(ECMSetupVersion)
0023 include(ECMGenerateHeaders)
0024 include(ECMAddQch)
0025 include(ECMMarkNonGuiExecutable)
0026 include(ECMQtDeclareLoggingCategory)
0027 include(ECMPoQmTools)
0028 include(ECMDeprecationSettings)
0029
0030 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0031
0032 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0033 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0034
0035 set(kglobalaccel_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kglobalaccel_version.h")
0036 ecm_setup_version(PROJECT VARIABLE_PREFIX KGLOBALACCEL
0037                         VERSION_HEADER "${kglobalaccel_version_header}"
0038                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6GlobalAccelConfigVersion.cmake"
0039                         SOVERSION 6)
0040
0041 # Dependencies
0042 set(REQUIRED_QT_VERSION 6.5.0)
0043 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus Gui Widgets)
0044
0045 set(HAVE_X11 0)
0046
0047 if(X11_FOUND AND XCB_XCB_FOUND)
0048     set(HAVE_X11 1)
0049 endif()
0050
0051 ecm_set_disabled_deprecation_versions(
0052     QT 6.5.0
0053     KF 5.102.0
0054 )
0055
0056 # Subdirectories
0057 ecm_install_po_files_as_qm(poqm)
0058
0059 add_subdirectory(src)
0060 if (BUILD_TESTING)
0061     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Test)
0062
0063     add_subdirectory(tests)
0064 endif()
0065
0066 # create a Config.cmake and a ConfigVersion.cmake file and install them
0067 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6GlobalAccel")
0068
0069 if (BUILD_QCH)
0070     ecm_install_qch_export(
0071         TARGETS KF6GlobalAccel_QCH
0072         FILE KF6GlobalAccelQchTargets.cmake
0073         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0074         COMPONENT Devel
0075     )
0076     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6GlobalAccelQchTargets.cmake\")")
0077 endif()
0078
0079 configure_package_config_file(
0080     "${CMAKE_CURRENT_SOURCE_DIR}/KF6GlobalAccelConfig.cmake.in"
0081     "${CMAKE_CURRENT_BINARY_DIR}/KF6GlobalAccelConfig.cmake"
0082     PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0083     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0084 )
0085
0086 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6GlobalAccelConfig.cmake"
0087                "${CMAKE_CURRENT_BINARY_DIR}/KF6GlobalAccelConfigVersion.cmake"
0088         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089         COMPONENT Devel )
0090
0091 install(EXPORT KF6GlobalAccelTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6GlobalAccelTargets.cmake NAMESPACE KF6:: )
0092
0093
0094 install(FILES ${kglobalaccel_version_header}
0095         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KGlobalAccel COMPONENT Devel)
0096
0097 include(ECMFeatureSummary)
0098 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0099
0100 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)