frameworks/kfilemetadata/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KFileMetaData VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake" ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(ECMAddTests)
0018 include(ECMGenerateExportHeader)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMAddQch)
0022 include(ECMQtDeclareLoggingCategory)
0023 include(ECMDeprecationSettings)
0024 include(CheckStructHasMember)
0025
0026 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0027
0028 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0029 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0030
0031 ecm_setup_version(PROJECT
0032                   VARIABLE_PREFIX KFILEMETADATA
0033                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kfilemetadata_version.h"
0034                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5FileMetaDataConfigVersion.cmake"
0035                   SOVERSION 3)
0036
0037 # Dependencies
0038 set(REQUIRED_QT_VERSION 5.15.2)
0039
0040 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG COMPONENTS Gui)
0041 set_package_properties(Qt${QT_MAJOR_VERSION}Gui PROPERTIES DESCRIPTION "Qt${QT_MAJOR_VERSION}: Gui component"
0042                        TYPE OPTIONAL
0043                        PURPOSE "Qt${QT_MAJOR_VERSION}::Gui is needed to build the AppImage extractor")
0044
0045 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS Xml)
0046 if (QT_MAJOR_VERSION STREQUAL "6")
0047     find_package(Qt6Core5Compat)
0048 endif()
0049
0050 find_package(KF5 ${KF_DEP_VERSION} COMPONENTS Archive)
0051 set_package_properties(KF5Archive PROPERTIES DESCRIPTION "KDE Frameworks 5: Archive Framework"
0052                        URL "https://download.kde.org/stable/frameworks/" TYPE OPTIONAL
0053                        PURPOSE "Archive is needed to build ODF and OOXML 2007 extractors")
0054
0055 find_package(KF5 ${KF_DEP_VERSION} COMPONENTS CoreAddons)
0056 set_package_properties(KF5CoreAddons PROPERTIES DESCRIPTION "KDE Frameworks 5: Core Addons Framework"
0057                        URL "https://download.kde.org/stable/frameworks/" TYPE REQUIRED
0058                        PURPOSE "Needed for the formatting of properties for display purposes")
0059
0060 find_package(KF5 ${KF_DEP_VERSION} COMPONENTS Config)
0061 set_package_properties(KF5Config PROPERTIES DESCRIPTION "KDE Frameworks 5: Config Framework"
0062                        URL "https://download.kde.org/stable/frameworks/" TYPE OPTIONAL
0063                        PURPOSE "Config is needed to build the AppImage extractor")
0064
0065 find_package(KF5 ${KF_DEP_VERSION} REQUIRED COMPONENTS I18n)
0066
0067 find_package(Poppler 0.12.1 COMPONENTS Qt${QT_MAJOR_VERSION})
0068 set_package_properties(Poppler PROPERTIES DESCRIPTION "A PDF rendering library"
0069                        URL "https://poppler.freedesktop.org/" TYPE OPTIONAL
0070                        PURPOSE "Support for PDF files")
0071
0072 find_package(Taglib 1.11.1)
0073 set_package_properties(Taglib PROPERTIES
0074                        TYPE OPTIONAL
0075                        PURPOSE "Support for music metadata")
0076
0077 find_package(LibExiv2 0.26)
0078 set_package_properties(LibExiv2 PROPERTIES
0079                        TYPE OPTIONAL
0080                        PURPOSE "Support for image metadata")
0081
0082 find_package(FFmpeg 57.48 COMPONENTS AVCODEC)
0083 if (AVCODEC_FOUND)
0084     find_package(FFmpeg 57.40 COMPONENTS AVFORMAT)
0085     if (AVFORMAT_FOUND)
0086         find_package(FFmpeg 55.27 COMPONENTS AVUTIL)
0087     endif()
0088 endif()
0089 set_package_properties(FFmpeg PROPERTIES DESCRIPTION "Video Tag reader"
0090                        URL "https://ffmpeg.org/" TYPE OPTIONAL
0091                        PURPOSE "Support for video metadata")
0092
0093 find_package(EPub)
0094 set_package_properties(EPub PROPERTIES DESCRIPTION "Ebook epub reader"
0095                        URL "https://sourceforge.net/projects/ebook-tools/" TYPE OPTIONAL
0096                        PURPOSE "Support for epub metadata")
0097
0098 find_package(CatDoc)
0099 set_package_properties(CatDoc PROPERTIES DESCRIPTION "catdoc executable"
0100                        URL "https://www.wagner.pp.ru/~vitus/software/catdoc/" TYPE RUNTIME
0101                        PURPOSE "Extract text from office 98 files - RUNTIME dependency")
0102
0103 if ( CMAKE_SYSTEM_NAME MATCHES "Linux" )
0104     find_package(Xattr)
0105     set_package_properties(Xattr PROPERTIES DESCRIPTION "library libattr "
0106         URL "https://savannah.nongnu.org/projects/attr"
0107         TYPE REQUIRED
0108         PURPOSE "Extended attribute shared library")
0109 endif()
0110
0111 find_package(QMobipocket 2.0)
0112 set_package_properties(QMobipocket PROPERTIES DESCRIPTION "Mobipocket epub reader"
0113                        URL "https://invent.kde.org/graphics/kdegraphics-mobipocket"
0114                        TYPE OPTIONAL PURPOSE "Support for mobi metadata")
0115
0116 find_package(libappimage 0.1.10 CONFIG)
0117 set_package_properties(libappimage PROPERTIES DESCRIPTION "Core library of the AppImage project"
0118                        URL "https://github.com/AppImage/libappimage"
0119                        TYPE OPTIONAL
0120                        PURPOSE "Needed to build the AppImage extractor"
0121                        )
0122
0123 ecm_set_disabled_deprecation_versions(
0124     QT 5.14.0 # TODO look into the QMap::insertMulti usage
0125     KF 5.97
0126 )
0127
0128 add_definitions(-DTRANSLATION_DOMAIN=\"kfilemetadata5\")
0129 add_subdirectory(src)
0130 if (BUILD_TESTING)
0131   add_subdirectory(autotests)
0132   add_subdirectory(tests)
0133 endif()
0134
0135 # Config files
0136 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5FileMetaData")
0137
0138 ki18n_install(po)
0139
0140 if (BUILD_QCH)
0141     ecm_install_qch_export(
0142         TARGETS KF5FileMetaData_QCH
0143         FILE KF5FileMetaDataQchTargets.cmake
0144         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0145         COMPONENT Devel
0146     )
0147     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5FileMetaDataQchTargets.cmake\")")
0148 endif()
0149
0150 include(CMakePackageConfigHelpers)
0151
0152 configure_package_config_file(
0153   "${CMAKE_CURRENT_SOURCE_DIR}/KF5FileMetaDataConfig.cmake.in"
0154   "${CMAKE_CURRENT_BINARY_DIR}/KF5FileMetaDataConfig.cmake"
0155   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0156 )
0157
0158 install(FILES
0159   "${CMAKE_CURRENT_BINARY_DIR}/KF5FileMetaDataConfig.cmake"
0160   "${CMAKE_CURRENT_BINARY_DIR}/KF5FileMetaDataConfigVersion.cmake"
0161   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0162   COMPONENT devel
0163 )
0164
0165 install(FILES
0166   ${CMAKE_CURRENT_BINARY_DIR}/kfilemetadata_version.h
0167   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData COMPONENT Devel
0168 )
0169
0170 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)